Страницы: 1
RSS
Узнать дату продажи последней единицы товара
 
Всем привет. Не могу подобрать формулу для поиска точной даты в которую будет продана последняя единица товара. Пример во вложении. Может у кого есть идеи? Заранее благодарен.
 
Формула массива
Код
=ИНДЕКС(B$7:G$7;ПОИСКПОЗ(1=1;СУММЕСЛИ(B$7:G$7;"<="&B$7:G$7;B8:G8)>=B4;))
Алексей М.
 
Спасибо большое!!!  А можно одной формулой узнать точную дату? например чтобы формула высчитала точный день. Еще раз заранее огромное спасибо!
 
Очень навороченная формула массива. Оптимизировать не стал.
Алексей М.
 
Цитата
poluks написал:
например чтобы формула высчитала точный день.
что значит точный день? Если сохраняется тренд или в день продают примерно равное количество, и если каждый день, то одно, а например за минусом выходных и праздников другое. Задача не конкретно описана.

у меня длиннее и результат иной =$B$7+MATCH(B4;MMULT(N(ROW(INDEX(A:A;$B$7):INDEX(A:A;EOMONTH($G$7;0)))>TRANSPOSE(ROW(INDEX(A:A;$B$7):INDEX(A:A;EOMONTH($G$7;0)))));VLOOKUP(A12;A8:G9;1+MATCH(ROW(INDEX(A:A;$B$7):INDEX(A:A;EOMONTH($G$7;0)));$B$7:$G$7);)/DAY(EOMONTH(ROW(INDEX(A:A;$B$7):INDEX(A:A;EOMONTH($G$7;0)));0))))-1
Изменено: БМВ - 04.06.2020 13:43:42
По вопросам из тем форума, личку не читаю.
 
БМВ, остаток на апрель 150, а на 30 дней апреля 400
=30*150/400=11,25
1.04.2020+11=12.04.2020
Алексей М.
 
Цитата
АlехМ написал:
остаток на апрель 150,
1000-200-250-300=250 вроде?
Зато появилась немного иная реализация. ща проверю
Изменено: БМВ - 04.06.2020 13:03:12
По вопросам из тем форума, личку не читаю.
 
Массив нарастающих сумм {200;450;750;1150;1650;2250}
вычитаем 1000
получаем массив {-800;-550;-250;150;650;1250}
150 на апрель
Алексей М.
 
АlехМ, не буду спорить, но на начало января 1000, а не 800 это после первого месяца 800
Алексей, введите не 1000 а 150 на начало года, ну явно не 08.01 должно выйти
Изменено: БМВ - 04.06.2020 13:35:27
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал:
не буду спорить
Почему нет. Ты прав.
Алексей М.
 
прав, а формулу подправил, ошибка на 1 день была, к первому января плюсовал же
По вопросам из тем форума, личку не читаю.
 
Вроде исправил. Интересно совпадут результаты
Алексей М.
 
для 1000 совпадает, а вот например для 150, 200 , 400 все время март. а 400 и 600 ваше с приколом :-)

Вариант более длинный, но возможно даже более быстрый может и INDEX($B$8:$G$9;MATCH(A12;$A$8:$A$9;);) зря использую.

=LOOKUP(B4;SUMIF($B$7:$G$7;"<"&$B$7:$G$7;INDEX($B$8:$G$9;MATCH(A12;$A$8:$A$9;);));$B$7:$G$7)+(B4-LOOKUP(B4;SUMIF($B$7:$G$7;"<"&$B$7:$G$7;INDEX($B$8:$G$9;MATCH(A12;$A$8:$A$9;);))))*DAY(EOMONTH(LOOKUP(B4;SUMIF($B$7:$G$7;"<"&$B$7:$G$7;INDEX($B$8:$G$9;MATCH(A12;$A$8:$A$9;);));$B$7:$G$7);0))/LOOKUP(B4;SUMIF($B$7:$G$7;"<"&$B$7:$G$7;INDEX($B$8:$G$9;MATCH(A12;$A$8:$A$9;);));INDEX($B$8:$G$9;MATCH(A12;$A$8:$A$9;);))
Изменено: БМВ - 04.06.2020 15:14:11
По вопросам из тем форума, личку не читаю.
 
БМВ, проверь пожалуйста.
Алексей М.
 
вот сейчас совпадают,
Но я тоже не стоял на месте
=MIN(IFERROR(ROUND(10^(LOG((B5-SUMIF($B$7:$G$7;"<"&$B$7:$G$7;B9:G9))/B9:G9*DAY(EOMONTH(TRANSPOSE($B$7:$G$7);0)))););1=0))+LOOKUP(B5;SUMIF($B$7:$G$7;"<"&$B$7:$G$7;B9:G9);$B$7:$G$7)

Сюрприз был что EOMONTH со столбцом работает а со строкой нет, пришлось ворочать а из-за краткости второй TRANSPOSE убрал и двумерный массив получается.
Изменено: БМВ - 04.06.2020 16:32:15
По вопросам из тем форума, личку не читаю.
 
БМВ, увлекло. Как остановиться?
Но совместными усилиями формула начинает нравиться
Алексей М.
 
Цитата
АlехМ написал:
Как остановиться?
Как как, только понять что кроме нас она никого и не интересует :-)

Алексей, при равенстве плохо работает. нгапример 750 должен быт по идее конец марта, это и моих вариантов касается
Изменено: БМВ - 04.06.2020 18:09:06
По вопросам из тем форума, личку не читаю.
 
У нас считает дату, когда товар кончился. Чтобы получить дату продажи последнего, достаточно отнять 1 секунду
("0:00:01") или 1/86400
Изменено: АlехМ - 04.06.2020 18:46:09
Алексей М.
 
тут надо понимать что должно быть. Но нашел еще вариант
2300 если взять, то есть за пределами плана, тут совсем чехарда
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал:
тут совсем чехарда
Формула считает, что каждый месяц после июня имеет количество товара (600 и 650) и дней (30) как в июне.
Изменено: АlехМ - 05.06.2020 09:06:32
Алексей М.
Страницы: 1
Наверх