Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Даты в формате " 2 декабря 2007 г" перевести в ДД.ММ.ГГГГ
 
#1
10.09.2020 12:56:04
есть большой список дат в формате " 2 декабря 2007 г" , не могу автоматически перевести эти даты в формат ДД.ММ.ГГГГ, только в ручную, но это муторно и долго, подскажите как это сделать.
 
 
 
#2
10.09.2020 13:05:28
Добрый день! Приложите пример в файле Excel.
На форуме есть много подобных тем.
Изменено: sokol92 - 10.09.2020 13:05:57
Владимир
 
 
 
#3
10.09.2020 13:10:03
высылаю файл
 
 
 
#4
10.09.2020 13:37:31
Пока  не пришли формулисты :)

Код
=--ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(E3 & " "; "та";"т");"ая";"ай");"я ";"ь");"г. ";"");"г ";"")
Владимир
 
 
 
#5
10.09.2020 13:38:41
Цитата
sokol92 написал:
Пока  не пришли формулисты
как то слишком просто и не массивно  :)
массивная
Код
=ЕСЛИОШИБКА(ДАТА(ПРАВСИМВ(СЖПРОБЕЛЫ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(E3;"г";"");".";""));4);МАКС(ЕЧИСЛО(ПОИСК({"Янв":"Фев":"Мар":"Апр":"Мая":"Июн":"Июл":"Авг":"Сен":"Окт":"Ноя":"Дек"};E3))*СТРОКА($1:$12));ЛЕВСИМВ(E3;ПОИСК(" ";E3)-1));E3)
Лень двигатель прогресса, доказано!!!
 
 
 
#6
10.09.2020 14:01:05
даты в офис 2019 ничем не отличаются от дат в остальных офисах нечего об этом писать в заголовке темы

название темы:
как дату содержащую название месяца преобразовать в стандартную дату?
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
 
 
#7
10.09.2020 14:57:10
Цитата
sokol92 написал:
Пока  не пришли формулисты
а они пришли  :D
=--(LEFT(E3;2)&SUBSTITUTE(MID(E3;FIND(" ";E3)+1;3);"я";"й")&LEFT(RIGHT(E3;7);4))
По вопросам из тем форума, личку не читаю.
 
 
 
#8
10.09.2020 15:33:18
А теперь подставляем в файл из #3...  :D  
Владимир
 
 
 
#9
10.09.2020 15:49:10
Цитата
sokol92 написал:
А теперь подставляем в файл из #3.
:evil:  Просто у меня маленький экран :-)
А разговоров то было
=--(LEFT(E3;2)&SUBSTITUTE(MID(E3;FIND(" ";E3)+1;3);"ая";"ай")&MID(E3;FIND(" ";E3;4)+1;4))
или даже так
=--(LEFT(E3;2)&SUBSTITUTE(MID(E3;FIND(" ";E3);4);"ая";"ай")&MID(E3;FIND(" ";E3;4);5))
Изменено: БМВ - 10.09.2020 16:48:26
По вопросам из тем форума, личку не читаю.
 
 
 
#10
10.09.2020 18:17:09
А компот строки 324-367? В #4 промахов нет. :oops:  
Изменено: sokol92 - 10.09.2020 18:24:12
Владимир
 
 
 
#11
10.09.2020 18:25:16
Цитата
sokol92 написал:
324-367
а это за предлами ТЗ :-)
=IFERROR(--E367;--(LEFT(E367;2)&SUBSTITUTE(MID(E367;FIND(" ";E367);4);"ая";"ай")&MID(E367;FIND(" ";E367;4);5)))
По вопросам из тем форума, личку не читаю.
 
 
 
#12
10.09.2020 18:31:33
Off. Мы в гимназиях не обучались, одну функцию (#4) освоили и ладно...
Владимир
 
 
 
#13
10.09.2020 18:34:13
Цитата
sokol92 написал:
одну функцию (#4) освоили и ладно..
подставщик  :D
По вопросам из тем форума, личку не читаю.
 
 
 
#14
10.09.2020 21:17:49
офф, извините
у моего деда на баяне было только две кнокпи: вкл и выкл
он на двух кнопках такие фуги наяривал....
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
 
 
#15
11.09.2020 11:31:36
спасибо всем большое за помощь
 
 
 
#16
11.09.2020 13:19:11
Как всегда опоздал. Мой вариант:
=--ПОДСТАВИТЬ(ЛЕВБ(E3;ПОИСК(" ";E3)+3)&ПСТР(E3;ПОИСК(" ";E3;5);5);"ая";"ай")
*А если год 2000+, то можно так:
=--ПОДСТАВИТЬ(ЛЕВБ(E3;ПОИСК(" ";E3)+3)&ПСТР(E3;ПОИСК(" 2";E3);5);"ая";"ай")
А если учитывать нижние даты, то:
=ЕСЛИ(E367<"";E367;--ПОДСТАВИТЬ(ЛЕВБ(E367;ПОИСК(" ";E367)+3)&ПСТР(E367;ПОИСК(" 2";E367);5);"ая";"ай"))
Изменено: Светлый - 11.09.2020 13:34:29
 
 
 
Страницы: 1
Наверх