Страницы: 1
RSS
Определение дополнительных баллов по лучшему времени
 
Нужна формула для добавления дополнительных баллов по итогам теста. Если все ответы правильные (20), то за лучшее время получают дополнительные баллы (за первое лучшее время - 2 балла, за второе лучшее время - 1,5 балла, за третье лучшее время - 1 балл, за 4 время - 0,5 баллов, за 5 время - 0,2 балла).
Формулу прописал, как мог, с помощью этого форума, только есть проблема. Если количество ответов не 20, то лучшее время не учитывается, а следующее лучшее время уже не первое и баллов добавляется не 2, а 1,5. Промежуточные результаты формула пропускает.
Если время у нескольких ответчиков одинаковое и все ответы верные, то начисляется одинаковое количество дополнительных баллов. Т.е. может быть несколько первых мест, несколько вторых и т.д.

Возможна ли формула или просто вручную сравнивать и прописывать дополнительные баллы?
 
уточнение участников оценки ограниченное число 5 или их может быть 100 или 200 или ...... и гипотетически все 100 или 200 ответили правильно

еще частный случай 10 человек набрало 20 баллов с различным временем
Вопрос дополнительные баллы начисляются только ТОП 5 по времени остальным 0
Лень двигатель прогресса, доказано!!!
 
Количество участников не ограничено. Если 5 (или 10, или 100 и т.д.) из них ответили правильно на 20 вопросов и у них одинаковое лучшее первое время, то всем добавляется 2 балла. Если есть хоть один неправильный ответ, то лучшее время не учитывается. Пример: 19 ответов - время 0,43 (дополнительных баллов нет), 20 ответов - время 0,48 (лучшее время, дополнительно 2 балла).
Объяснил, как мог...

Цитата
Сергей написал:  дополнительные баллы начисляются только ТОП 5 по времени остальным 0
Остальным 0. Но ТОП 5 может состоять не обязательно из 5 человек. Есть топ дополнительных баллов - 5 значений: 2; 1,5; 1; 0,5; 0,2.

Цитата
10 человек набрало 20 баллов с различным временем
Из них и выбираются те, кому начисляются дополнительные баллы в зависимости от лучшего времени.
 
Получаем ранг по убыванию:
=РАНГ(D6;$D$6:$D$16)+РАНГ(E6;$E$6:$E$16;1)*0,001
Дальше должно быть просто: сравниваем ранг с диапазоном рангов функцией НАИБОЛЬШИЙ или НАИМЕНЬШИЙ
Например:
=МАКС(ЕСЛИ(НАИМЕНЬШИЙ($F$6:$F$16;{1;2;3;4;5})=F6;{2;1,5;1;0,5;0,2}))
 
еще вариант
Код
=ЕСЛИОШИБКА(ЕСЛИ(D6=20;ВЫБОР(ПОИСКПОЗ(E6;НАИМЕНЬШИЙ(ЕСЛИ($D$6:$D$16=20;$E$6:$E$16);СТРОКА($1:$5));0);2;1,5;1;0,5;0,2);"");"")
Лень двигатель прогресса, доказано!!!
 
Сергей, было бы отлично! Но пропустило дополнительный балл 0.5. А при добавлении дополнительных участников пропускает другие баллы((
vikttur, нет, не вышло. Та же ситуация с добавлением участников: пропадают промежуточные дополнительные баллы

Цитата
vikttur написал: =РАНГ(D6;$D$6:$D$16)+РАНГ(E6;$E$6:$E$16;1)*0,001
Эта формула подходит!!! А дальше надо результатам с одинаковыми значениями назначить одинаковые дополнительные баллы.

20 ответов - 0,43 - 2 балла
20 ответов - 0,43 - 2 балла
20 ответов - 0,48 - 1,5 балла
20 ответов - 0,48 - 1,5 балла
20 ответов - 1,02 - 1 балл
20 ответов - 1,2 - 0,5 баллов
20 ответов - 1,2 - 0,5 баллов
20 ответов - 3 - 0,2 балла
Так должно получиться.
При любом количестве первых мест, каждому из них добавляется 2 балла, за любое количество вторых мест каждому 1,5 балла...
 
Вот такая формула в конце получилась. Всё сошлось...

=ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20<=F6)*F$6:F$20;F$6:F$20)>0))=1;2;ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20<=F6)*F$6:F$20;F$6:F$20)>0))=2;1,5;ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20<=F6)*F$6:F$20;F$6:F$20)>0))=3;1;ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20<=F6)*F$6:F$20;F$6:F$20)>0))=4;0,5;ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20<=F6)*F$6:F$20;F$6:F$20)>0))=5;0,2;ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20<=F6)*F$6:F$20;F$6:F$20)>0))>5;0))))))

Можно ли её как-то уменьшить... Всё таки хочу не делать промежуточный столбец из ранга, а всё влепить в одну формулу :oops:  
 
пока только с доп столбцом  
Лень двигатель прогресса, доказано!!!
 
Оба варианта отличные!!! Спасибо за участие и помощь! Буду пытаться свести столбцы воедино.
Если вдруг у кого-то еще появятся идеи, с удовольствием выслушаю)) ;)  
 
Вариант доп. формулы:
=МАКС(ЕСЛИ(РАНГ(F6;$F$6:$F$20;1)-СЧЁТЕСЛИ($F$6:F6;"<"&F6)+СУММ(1/СЧЁТЕСЛИ($F$6:F6;$F$6:F6))-СЧЁТЕСЛИ($F$6:F6;">"&F6)-1={1;2;3;4;5};{2;1,5;1;0,5;0,2}))
СЧЕТЕСЛИ можно, наверное, сократить...
тестирование2.xlsx (11.36 КБ)

P.S.
Алек Ларин, если Вашу формулу ужать...
=МАКС(ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20<=F6)*F$6:F$20;F$6:F$20)>0))={1;2;3;4;5};{2;1,5;1;0,5;0,2}))

Сергей, решение в №8: если результатов с максимальным количеством (20) меньше 5 - беда )
 
Спасибо большое! Доп.столбец просто скрою... Чтоб никто не догадался :D  :D  :D  
 
Цитата
vikttur написал:
Алек Ларин , если Вашу формулу ужать...=МАКС(ЕСЛИ(СУММ(--(ЧАСТОТА((F$6:F$20 0))={1;2;3;4;5};{2;1,5;1;0,5;0,2}))
Хорошо, что моя формула всё таки тоже сгодилась)))
Спасибо!

Теперь предстоит сложный выбор из получившихся нескольких отличных вариантов ;)  :D

Еще раз всем спасибо!
Страницы: 1
Наверх