Sub СкрытьПустые()
    Dim shG As Worksheet: Set shG = Worksheets("Главная")
    Dim shV As Worksheet: Set shV = Worksheets("вспомогательная")
    Dim y As Long
    Dim a As Variant
    Dim dic As Object: Set dic = CreateObject("Scripting.Dictionary")
    With shG
        y = .Cells(.Rows.Count, 3).End(xlUp).Row
        a = .Range(.Cells(1, 2), .Cells(y, 3))
    End With
    
    For y = 1 To UBound(a, 1)
        If Not IsEmpty(a(y, 2)) Then
            dic.Item(a(y, 1)) = 0
        End If
    Next
    Erase a
    
    With shV
        .Cells.EntireRow.Hidden = False
        y = .Cells(.Rows.Count, 1).End(xlUp).Row
        a = .Range(.Cells(1, 1), .Cells(y, 2))
        For y = 1 To UBound(a, 1)
            If Not dic.Exists(a(y, 1)) Then
                .Rows(y).EntireRow.Hidden = True
            End If
        Next
        .Select
    End With
End Sub

Sub Hide()
    Dim cell As Range
    Application.ScreenUpdating = False                              'отключаем обновление экрана для ускорения
    For Each cell In ActiveSheet.UsedRange.Rows(1).Cells            'проходим по всем ячейкам первой строки
        If cell.Value = "x" Then cell.EntireColumn.Hidden = True    'если в ячейке x - скрываем столбец
    Next
    For Each cell In ActiveSheet.UsedRange.Columns(1).Cells         'проходим по всем ячейкам первого столбца
        If cell.Value = "x" Then cell.EntireRow.Hidden = True       'если в ячейке x - скрываем строку
    Next
    Application.ScreenUpdating = True
End Sub
 
Sub Show()
    Columns.Hidden = False   'отменяем все скрытия строк и столбцов
    Rows.Hidden = False
End Sub