Sub CombineWorkbooks()
    Dim FilesToOpen, wbImportFrom As Workbook, iFile As Long, counter As Long, SheetCopyName As String
     
    If MsgBox("Собрать листы 'ABCDE-auto' из файлов?", vbQuestion + vbYesNo, "Вопрос") = vbNo Then Exit Sub
    
    'вызываем диалог выбора файлов откуда будем брать данные
    FilesToOpen = Application.GetOpenFilename(FileFilter:="All files (*.*), *.*", MultiSelect:=True, Title:="Укажите файлы")
  
    If TypeName(FilesToOpen) = "Boolean" Then
        MsgBox "Не выбрано ни одного файла!", vbExclamation, "Внимание"
        Exit Sub
    End If
    
    SheetCopyName = "ABCDE-auto" 'название листа, которое будем собриать
    counter = 0 'счётчик обработанных файлов
      
    Application.ScreenUpdating = False 'отключение обновления экрана
    
    'проходим по всем выбранным файлам
    For iFile = 1 To UBound(FilesToOpen)
        'если в список попал общий файл, то пропускаем его
        If FilesToOpen(iFile) <> ThisWorkbook.FullName Then
            Set wbImportFrom = Workbooks.Open(Filename:=FilesToOpen(iFile), ReadOnly:=True)
            'проверяем на наличие листа ABCDE-auto в файле
            If SheetExist(wbImportFrom.Name, SheetCopyName) Then
                counter = counter + 1 'увеличиваем счётчик на 1
                'копируем лист в общий файл
                wbImportFrom.Worksheets(SheetCopyName).Copy ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count)
            End If
            'закрываем очередной файл и переходим к другому файлу
            wbImportFrom.Close savechanges:=False
        End If
    Next iFile
    
    Application.ScreenUpdating = True
    MsgBox "Данные из " & counter & " файлов собраны!", vbInformation, "Конец"
End Sub

Function SheetExist(WB As String, iSheetName As String) As Boolean
    On Error Resume Next
    With Workbooks(WB).Worksheets(iSheetName): End With
    SheetExist = (Err = 0)
    Err.Clear
    On Error GoTo 0
End Function