Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Суммирование по нескольким условиям из разных таблиц
 
#1
19.02.2021 11:56:53
Добрый день. Прошу помощи с задачкой. По поиску пробежался, тем похожих много, но к моему случаю не смог применить.

Есть две таблицы с данными, и третья итоговая

В третьей таблице по заданным условиям, нужно просуммировать "Количество" из таблицы 2.
Сложность в том что в таблице 2 содержится информация только по одному из условий, а все остальные данные содержатся в таблице 1.
Возможно уложиться в одну формулу без проставления данных из Таблицы 1 в таблицу 2?
 
 
 
#2
19.02.2021 12:11:11
a4ag,
мой вариант с дополнительным столбцом
 
 
 
#3
19.02.2021 12:14:38
МАССИВНАЯ ввести Q7 и протянуть вниз
Код
=СУММ(СУММЕСЛИ($C$20:$C$29;ИНДЕКС($C$7:$C$16;ПОИСКПОЗ(L7&N7&O7&P7;$B$7:$B$16&$D$7:$D$16&$E$7:$E$16&$F$7:$F$16;0)):ИНДЕКС($C$7:$C$16;ПОИСКПОЗ(L7&N7&O7&P7;$B$7:$B$16&$D$7:$D$16&$E$7:$E$16&$F$7:$F$16;0)+СЧЁТЕСЛИМН($B$7:$B$16;L7;$D$7:$D$16;N7;$E$7:$E$16;O7;$F$7:$F$16;P7)-1);$G$20:$G$29))
Лень двигатель прогресса, доказано!!!
 
 
 
#4
19.02.2021 22:55:44
Еще один летучий как эфир вариант.
Код
=СУММ(($C$20:$C$29=ТРАНСП(СМЕЩ(ИНДЕКС($C$7:$C$16;ПОИСКПОЗ(1;(L7=$B$7:$B$16)*(N7=$D$7:$D$16)*(O7=$E$7:$E$16)*(P7=$F$7:$F$16);0));0;0;СЧЁТЕСЛИМН($B$7:$B$16;L7;$D$7:$D$16;N7;$E$7:$E$16;O7;$F$7:$F$16;P7))))*$G$20:$G$29)
 
 
 
#5
18.08.2023 20:29:47
а вставить просмотрX в формулу можно?
что бы не громоздить формулу
Изменено: Vit25 - 18.08.2023 20:32:51
Использую Excel 2021_Версия 2404
 
 
 
#6
18.08.2023 21:01:18
Формула массива:
=СУММ(СУММЕСЛИ(A$13:A$20;ЕСЛИ(A7=D$13:D$17;E$13:E$17);B$13:B$20))
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
 
 
#7
18.08.2023 23:12:10
Цитата
написал:
Формула массива:

Поправьте, пожалуйста,  формулу.
Использую Excel 2021_Версия 2404
 
 
 
#8
19.08.2023 05:40:21
Цитата
написал: Поправьте, пожалуйста,  формулу.
Максим ответил на вашу закрытую тему
еще вам  { }:
=СУММ(B$13:B$20*(A$13:A$20=ТРАНСП(ЕСЛИ(D$13:D$17=A7;E$13:E$17))))
 
 
 
#9
19.08.2023 19:33:40
Максим В. и Павел \Ʌ/
Спасибо Вам!
Пока на данном форуме не давно, поэтому не нашел кнопку благодарности.
Использую Excel 2021_Версия 2404
 
 
 
#10
19.08.2023 19:47:44

Скажите, что обозначают символы { } в формуле

При этом они пропадают в формуле при двойном нажатии по ячейке или строке формулы

Использую Excel 2021_Версия 2404
 
 
 
#11
19.08.2023 19:53:42
Цитата
написал:
Скажите, что обозначают символы { } в формуле

Это "отличительный признак формулы массива"
Об этих формулах можно прочесть тут:

https://www.planetaexcel.ru/techniques/2/91/
 
 
 
#12
19.08.2023 20:00:24
DAB, благодарю!
Использую Excel 2021_Версия 2404
 
 
 
#13
19.08.2023 20:56:08
Ну и еще без массивного ввода:
Код
=СУММПРОИЗВ(B$13:B$20*СЧЁТЕСЛИМН(E$13:E$17;A$13:A$20;D$13:D$17;A7))
 
 
 
#14
19.08.2023 21:26:11
memo, благодарю!
Использую Excel 2021_Версия 2404
 
 
 
#15
24.08.2023 19:51:36
Если мы сравниваем наименования в котором присутствует дополнительные знаки то устанавливаем “*” & “*” но вот не задача это не работает если есть перед ним равенство, допустим:

= ЕСЛИ(D13:D17="*" & A7 & "*"…..)

Или = "*" & A7 & "*"=A8, что значит ="*" & Первый & "*"= Первый региональный

В формулах работает если данный критерий отбора "*" & A7 & "*" стоит после ;
Пример:
СЧЁТЕСЛИМН(E13:E17;A13:A20;D13:D17;"*" & A7 & "*")

Если возможность это обойти?
Использую Excel 2021_Версия 2404
 
 
 
#16
25.08.2023 08:42:54
=СУММ(B$13:B$20*(A$13:A$20=ТРАНСП(ЕСЛИ(ЕЧИСЛО(ПОИСК(A7&"*";D$13:D$17));E$13:E$17))))
 
 
 
#17
25.08.2023 10:30:25
Power Query
Код
let
    Source = Table.NestedJoin(Table1,{"№ точки"},Table2,{"№ точки"},"NewColumn",JoinKind.LeftOuter),
    #"Expanded NewColumn" = Table.ExpandTableColumn(Source, "NewColumn", {"Количество"}, {"NewColumn.Количество"}),
    #"Grouped Rows" = Table.Group(#"Expanded NewColumn", {"№ объекта", "Наименование", "Тип", "Тариф"}, {{"Количество", each List.Sum([NewColumn.Количество]), type number}})
in
    #"Grouped Rows"
Изменено: jakim - 25.08.2023 10:31:33
 
 
 
Страницы: 1
Наверх