let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    ChangedType = Table.TransformColumnTypes(Source,{{"Время_пинг", type datetime}}),
    SortedRows = Table.Sort(ChangedType,{{"Время_пинг", Order.Descending}}),
    GroupedRows = Table.Group(
        SortedRows, 
        {"True/False"}, 
        {{"tab", each if List.Last([#"True/False"]) 
                then Table.FromColumns( 
                        Table.ToColumns(Table.Sort(_,{{"Время_пинг", Order.Ascending}})) & {{List.Min([Время_пинг])}, {List.Max([Время_пинг])}}, 
                        Table.ColumnNames(_) & {"Время начала", "Время окончания"} ) 
                else _}},
        0,
        (a,b)=>Number.From(not a[#"True/False"] and not b[#"True/False"])),
    Combine = Table.Combine( GroupedRows[tab] ),
    SortedTable = Table.Sort(Combine,{{"Время_пинг", Order.Ascending}})
in
    SortedTable

let
    Источник = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    #"Измененный тип" = Table.TransformColumnTypes(Источник,{{"ID", Int64.Type}, {"Время_пинг", type datetime}, {"Значение, сек", Int64.Type}, {"Норматив, сек", Int64.Type}, {"True/False", type logical}}),
    Custom1 = Table.FromColumns( 
        Table.ToColumns( #"Измененный тип" ) & {List.RemoveLastN( {false} & #"Измененный тип"[#"True/False"], 1 )}, 
        Table.ColumnNames( #"Измененный тип" ) & {"t_f_prev"} ),
    #"Сортированные строки2" = Table.Sort(Custom1,{{"ID", Order.Ascending}, {"Время_пинг", Order.Ascending}}),
 
    #"Добавлен пользовательский объект" = Table.AddColumn(#"Сортированные строки2", "время начала", each if [#"True/False"]=true and [t_f_prev]=false then [Время_пинг] else null, type datetime),
    #"Добавлен пользовательский объект1" = Table.AddColumn(#"Добавлен пользовательский объект", "время конца", each if [#"True/False"]=false and [t_f_prev]=true then [Время_пинг] else null),
    #"Сгруппированные строки" = 
        Table.Group(
            #"Добавлен пользовательский объект1", 
            {"ID"}, 
            {{
                "group", 
                 each Table.FillUp(Table.Sort(_,{{"Время_пинг", Order.Ascending}}),{"время конца"}), 
                 type table [Время_пинг=datetime, #"Значение, сек"=Int64.Type, #"Норматив, сек"=Int64.Type, #"True/False"=logical, #"t_f_prev"=logical, время начала=datetime, время конца=datetime]
            }}
        ),
    #"Развернутый элемент group" = Table.ExpandTableColumn(#"Сгруппированные строки", "group", {"Время_пинг", "Значение, сек", "Норматив, сек", "True/False", "t_f_prev", "время начала", "время конца"}),
    #"Замененное значение" = Table.ReplaceValue(#"Развернутый элемент group",each [время конца],each if [#"True/False"]=true and [t_f_prev]=false then [время конца] else null,Replacer.ReplaceValue,{"время конца"}),
    #"Удаленные столбцы" = Table.RemoveColumns(#"Замененное значение",{"t_f_prev"}),
    #"Измененный тип1" = Table.TransformColumnTypes(#"Удаленные столбцы",{{"время конца", type datetime}})
in
    #"Измененный тип1"

let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    Custom1 = let a=Source, b= Table.ToColumns(a) , c = {{null}&List.RemoveLastN(List.Last(b),1)},
                  d= b&c, e= Table.FromColumns(d, Table.ColumnNames(a)&{"a"}) in e,
    #"Grouped Rows" = Table.Group(Custom1, {"True/False","a"},{{"b", each 
       let d=_, c1= if d[#"True/False"]{0}=false then null else d[Время_пинг]{0}, 
      c2=List.Last(Table.RemoveLastN(d,each [a] <> true)[Время_пинг]),
   e=Table.ToColumns(d)&{{c1}}&{{c2}}, f=Table.ColumnNames(d)&{"время начала","время конца"} 
   in Table.FromColumns(e,f)
    }},0,(a,b)=> Number.From( b[#"True/False"] and not b[#"a"])),
    Custom2 = Table.Combine(#"Grouped Rows"[b]),
    #"Removed Columns" = Table.RemoveColumns(Custom2,{"a"})
in
    #"Removed Columns"