Страницы: 1
RSS
Вытянуть число с текста, после знака, Формула для вытаскивания числа после определенных знаков
 
Добрый день!
Какой формулой можно вытащить число после знака / и если к числу подставленный не раздельно текс
Пример:
КОРОБОЧНЫЕ   КОНФЕТЫ Стрела Подольская ВКФ 200г /10шт
Мне же нужно вытащить только 10, длинна текста бывает разная.
Добавляю файл у вложения.
Заранее спасибо!
 
Korifan, Статья или «оставить только числа excel» — запрос для гугла
Изменено: Jack Famous - 09.06.2021 15:21:07
Во всех делах очень полезно периодически ставить знак вопроса к тому, что вы с давних пор считали не требующим доказательств (Бертран Рассел) ►Благодарности сюда◄
 
Код
=ЗНАЧЕН(ПСТР(ПСТР(G9;НАЙТИ("/";G9)+1;ДЛСТР(G9));1;МАКС(ЕСЛИОШИБКА(НАЙТИ("шт";ПСТР(G9;НАЙТИ("/";G9)+1;ДЛСТР(G9)))-1;0);ЕСЛИОШИБКА(НАЙТИ("пак";ПСТР(G9;НАЙТИ("/";G9)+1;ДЛСТР(G9)))-1;0))))
 
Код
=--СЖПРОБЕЛЫ(ПРАВСИМВ(ПОДСТАВИТЬ(ЛЕВСИМВ(G9;МАКС(ЕСЛИОШИБКА(ПОИСК({"шт";"пак"};G9)-1;)));"/";ПОВТОР(" ";15));15))

Вводить через CTRL+SHIFT+ENTER
Изменено: memo - 09.06.2021 15:41:26
 
Код
=ПРОСМОТР(9^9;--ПСТР(ПСТР(G9;ПОИСК("/";G9)+1;9);СТРОКА($1:$99);МАКС(ЕСЛИОШИБКА(ПОИСК({0:1:2:3:4:5:6:7:8:9};ПСТР(G9;ПОИСК("/";G9)+1;9));0))))
=ПРОСМОТР(9^9;--ПСТР(ПСТР(G9;ПОИСК("/";G9)+1;9);СТРОКА($1:$99);СЧЁТ(ПОИСК({0:1:2:3:4:5:6:7:8:9};ПСТР(G9;ПОИСК("/";G9)+1;9)))))
=LET(a;ПСТР(G9;ПОИСК("/";G9)+1;9);-ПРОСМОТР(9^9;-ПСТР(a;СТРОКА($1:$99);МАКС(ЕСЛИОШИБКА(ПОИСК({0:1:2:3:4:5:6:7:8:9};a);0)))))
=LET(a;ПСТР(G9;ПОИСК("/";G9)+1;9);ПРОСМОТР(9^9;--ПСТР(a;СТРОКА($1:$99);СЧЁТ(ПОИСК({0:1:2:3:4:5:6:7:8:9};a)))))
Изменено: Тимофеев - 09.06.2021 16:39:38
 
до кучи
Код
=ПСТР(ПСТР(G9;ПОИСК("/";G9)+1;5);1;МАКС(ЕЧИСЛО(--ПСТР(ПСТР(G9;ПОИСК("/";G9)+1;5);СТРОКА($1:$5);1))*СТРОКА($1:$5)))
Лень двигатель прогресса, доказано!!!
 
Добавление к куче, но только в рамках выложенного примера.
Код
=--СЖПРОБЕЛЫ(ПОДСТАВИТЬ(ПСТР(G9;МАКС(ЕСЛИОШИБКА(ПОИСК({"шт";"па"};G9)-3;));3);"/";""))
 
Массивная
=MAX(IFERROR(--LEFT(TRIM(RIGHT(SUBSTITUTE(G9;"/";REPT(" ";99));99));ROW($1:$15));)) и плевать на штуки, пачки упаковки, кг и ....
Изменено: БМВ - 09.06.2021 20:33:13
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал:
кг и ....
Так окромя косой черты больше ничего и не осталось  :D
 
Цитата
memo написал:
больше ничего и не осталось
это в данном примере.
По вопросам из тем форума, личку не читаю.
Страницы: 1
Наверх