Страницы: 1 2 След.
RSS
Вывести список повторяющихся значний
 
Всем привет!
Нужна ваша помощь.
необходимо вывести список дублирующихся значений в другом столбце, без повторений.
Изменено: vikttur - 02.09.2021 22:34:13
 
Как вариант - Сводная таблица с сортировкой

По вопросу темы "ПОИСК НАИБОЛЕЕ ПОВТОРЯЮЩЕГОСЯ ЗНАЧЕНИЯ В EXCEL", Для чисел подойдет:
Код
=МОДА(A2:A910)
Изменено: MCH - 02.09.2021 16:35:31
 
Цитата
Alex Рубанов написал:
ПОИСК НАИБОЛЕЕ ПОВТОРЯЮЩЕГОСЯ ЗНАЧЕНИЯ В EXCEL
и
Цитата
Alex Рубанов написал:
вывести список дублирующихся значений в другом столбце
не состыковки
используйте сводную таблицу и все
Изменено: Mershik - 02.09.2021 16:38:21
Не бойтесь совершенства. Вам его не достичь.
 
Код
B2    =ЕСЛИОШИБКА(ИНДЕКС(A:A;ПОИСКПОЗ(СТРОКА(1:1);C:C;0));"")
C2    =C1--(СЧЁТЕСЛИМН($A$1:A1;A2)=0)
 
подскажите, пожалуйста, а если есть несколько повторяющихся значений?
 
Цитата
Alex Рубанов написал:
если есть несколько повторяющихся значений?
Цитата
Mershik написал:
используйте сводную таблицу и все
Не бойтесь совершенства. Вам его не достичь.
 
сводная
 
спасибо за помощь, но нужна именно формула, которая  будет выводить только наиболее часто встречающиеся варианты без дублей.
 
Цитата
Alex Рубанов написал:
выводить только наиболее часто встречающиеся варианты
Насколько наиболее?
Изменено: vikttur - 02.09.2021 16:57:37
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
то есть, только те которые повторяются.
 
Alex Рубанов,
3 формулы на выбор:
Код
=MODE(IF(COUNTIF($B$1:B1;$A$2:$A$910)=0;$A$2:$A$910))

Код
=MODE(IF(ISERROR(MATCH($A$2:$A$910;$C$1:C1;0));$A$2:$A$910))

Код
=MODE(IF(1-ISNUMBER(MATCH($A$2:$A$910;$D$1:D1;0));$A$2:$A$910))

Все вводятся через CTRL+SHIFT+ENTER.
 
Можно такой массивной формулой:
Код
=--ПРАВБ(МАКС(ЕСЛИ(СЧЁТЕСЛИ(B$1:B1;A$2:A$910);;СЧЁТЕСЛИ(A$2:A$910;A$2:A$910)*10^8+A$2:A$910));8)
 
Светлый, Начиная с 137 строки формула выводит неповторяющиеся числа, а ТС вроде просил
Цитата
Alex Рубанов написал:
только те которые повторяются.
 
Цитата
memo написал:
Начиная с 137 строки формула выводит неповторяющиеся числа
Пусть выводятся нули. Их можно скрыть:
Код
=--ПРАВБ(МАКС(ЕСЛИ((СЧЁТЕСЛИ(B$1:B1;A$2:A$910)=0)*(СЧЁТЕСЛИ(A$2:A$910;A$2:A$910)>1);СЧЁТЕСЛИ(A$2:A$910;A$2:A$910)*10^8+A$2:A$910));8)
=--ПРАВБ(МИН(ЕСЛИ(СЧЁТЕСЛИ(B$1:B1;A$2:A$910);;-ТЕКСТ(СЧЁТЕСЛИ(A$2:A$910;A$2:A$910)*10^8+A$2:A$910;"[>2E8]0;;\0")));8)
Изменено: Светлый - 02.09.2021 20:18:20
 
Светлый,
Сейчас то самое) Кстати, на моем компе с 4-мя архаичными ядрами последняя формула считает заметно шустрее, чем первая.
 
А вот так сортирует не по встречаемости, а по величине, но больше 1 раза встречается.
Только для представленных данных:
Код
=НАИБОЛЬШИЙ((ЧАСТОТА(A$2:A$910;СТРОКА($1:$400000))>1)*СТРОКА($1:$400001);СТРОКА(F1))
 
спасибо большое всем за помощь)
 
Цитата
Светлый написал:
Код
[>2E8]0
     Здравствуйте.
     Простите, что влезаю, но не подскажете ли, что значат эти квадратные скобки?
 
для коллекции:
Поиск и подсчет самых частых значений
Частотный анализ по интервалам функцией ЧАСТОТА (FREQUENCY)
 
Никто не знает, что значат квадратные скобки?
 
Неопытный_Экселист

В квадратных скобках имя столбца в Умных таблицах
http://www.planetaexcel.ru/techniques/2/136/
 
DJMC,
Большущее спасибо. Действительно с умными таблицами мне пока работать не доводилось?
 
Цитата
Неопытный_Экселист: [>2E8]0
не подскажете ли, что значат эти квадратные скобки?
Цитата
DJMC: В квадратных скобках имя столбца в Умных таблицах
вы как всегда — в точку!  :D
P.S.: далеко не только столбца, если на то пошло

Неопытный_Экселист, похоже на экспоницеальную запись числа типа > 2 * 10 ^ 8, но это не точно  ;)
Я не формулист всё-таки)))

Цитата
P.P.S.: Неопытный_Экселист: DJMC , Большущее спасибо
8-0 помогло, значит
Прикольно, учитывая, что в примере никаких умных таблиц в помине не было. Ну ок - вам виднее
Изменено: Jack Famous - 06.09.2021 11:00:32
Во всех делах очень полезно периодически ставить знак вопроса к тому, что вы с давних пор считали не требующим доказательств (Бертран Рассел) ►Благодарности сюда◄
 
Цитата
Jack Famous написал:
но это не точно
А кто подскажет точно? Просто впервые вижу применение квадратных скобок в формулах.
 
Неопытный_Экселист, а вы с какой целью стараетесь похватать куски "фишек и приёмов" отовсюду, не разобравшись с имеющимися знаниями?
Собираетесь применять в своих формулах? Это опасная практика …
Во всех делах очень полезно периодически ставить знак вопроса к тому, что вы с давних пор считали не требующим доказательств (Бертран Рассел) ►Благодарности сюда◄
 
Цитата
Jack Famous написал:
Собираетесь применять в своих формулах?
Просто в книгах не встречал (может, правда, плохо читал?). А в формуле увидел - и захотелось узнать, каково их назначение. Кто-нибудь может подсказать, зачем в формуле из поста 14 используются квадратные скобки?
 
Цитата
Неопытный_Экселист написал:
Кто-нибудь может подсказать, зачем в формуле из поста  14  используются квадратные скобки?
Квадратные скобки относятся к функции ТЕКСТ для формата вычисляемого числа,
в части формулы: ТЕКСТ(...вычисления...;"[>2E8]0;;\0") будет возвращаться число в текстовом виде, если оно больше значения 200 млн (2*10^8) и "0" во всех остальных случаях
при этом ...вычисления... рассчитываются по формуле: СЧЁТЕСЛИ(A$2:A$910;A$2:A$910)*10^8+A$2:A$910
т.е. количество повторов каждого значения умножается на 10^8 и прибавляется само значение, для всех случаев повторов более 2 (значение более чем 2*10^8), сохраняем число иначе "зануляем" его с помощью функции ТЕКСТ
 
Цитата
MCH написал:
в части формулы: ТЕКСТ(...вычисления...;"[>2E8]0;;\0") будет возвращаться число в текстовом виде, если оно больше значения 200 млн (2*10^8) и "0" во всех остальных случаях
8-0
Никогда бы не подумал, что можно так задавать условия в функции. Вроде просто задаём формат - ан нет, с условием. Большущее спасибо! Пошёл дальше (и внимательнее) книжки читать...
Изменено: Неопытный_Экселист - 06.09.2021 13:18:37
 
Цитата
MCH: будет возвращаться число в текстовом виде, если оно больше значения 200 млн
не заметил, что это аргумент ТЕКСТа — спасибо, я тоже не знал, что форматом можно условие выставить. Прикольно  :idea:  ;)
Во всех делах очень полезно периодически ставить знак вопроса к тому, что вы с давних пор считали не требующим доказательств (Бертран Рассел) ►Благодарности сюда◄
 
Цитата
Jack Famous написал:
что форматом можно условие выставить
    Не, тут похоже формат выставляется ПО условию.
Страницы: 1 2 След.
Наверх