let
   source =
      Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],

   tableTransformColumns =
      Table.TransformColumns(
         source,
         {
            {"Дата заезда", DateTime.Date, type date},
            {"Дата выезда", DateTime.Date, type date}
         }),

   tableSelectRows =
      Table.SelectRows(
         tableTransformColumns,
         each
            [Дата заезда] <> [Дата выезда]),

   addListDates = 
      Table.AddColumn(
         tableSelectRows,
         "ListDates",
         each
            List.Dates([Дата заезда], Number.From([Дата выезда] - [Дата заезда]) + 1, #duration(1, 0, 0, 0))),

   expandListDates =
      Table.ExpandListColumn(
         addListDates,
         "ListDates"),

   tableGroup =
      Table.Group(
         expandListDates,
            {"ListDates"},
            {{"Количество",
            each
               Table.RowCount(_), Int64.Type}}),

    ListDatesToDates =
      Table.TransformColumnTypes(
         tableGroup,
         {
            {"ListDates", type date}
         })
in
    ListDatesToDates