Option Explicit

'Для старта.
Sub Start()
    PrintWord GetDirection() + 1
End Sub
'Для смены направления перевода.
Sub ChangeDirection()
    With Sheets("Проверка").Range("E1")
        Application.EnableEvents = False
        If IsEmpty(.Value) Then
            .Value = "eng"
        Else
            .Value = Empty
        End If
        Application.EnableEvents = True
    End With
End Sub
Function GetDirection() As Byte
    Dim direction As Byte
    With Sheets("Проверка").Range("E1")
        If IsEmpty(.Value) Then
            direction = 0
        Else
            direction = 1
        End If
    End With
    GetDirection = direction
End Function

Function GetArr() As Variant
    Dim arr As Variant
    Dim y As Long
    With Sheets("Словарь")
        y = .Cells(.Rows.Count, 1).End(xlUp).Row
        arr = .Range(.Cells(1, 1), .Cells(y, 2))
    End With
    GetArr = arr
End Function

Sub PrintWord(ByVal x As Byte)
    Dim arr As Variant
    Dim y As Long
    arr = GetArr()
    If x < 1 Or x > UBound(arr, 2) Then x = 1
    
    With Sheets("Проверка")
        y = .Cells(.Rows.Count, 1).End(xlUp).Row
        y = y + 1
        If y > 30 Then Exit Sub
        Dim r As Range
        Set r = .Cells(y, 1)
        Randomize
        y = Rnd() * (UBound(arr, 1) - 1) + 1
        If y < 2 Then y = UBound(arr, 1)
        r.Value = arr(y, x)
        .Select
        Application.EnableEvents = False
        r.Cells(1, 2).Select
        Application.EnableEvents = True
    End With
End Sub

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Cells.Count = 1 Then
        If Target.Column = 2 Then
            If Target.Row <= 30 Then
                If Target.Value <> "" Then
                    Dim arr As Variant
                    arr = GetArr()
                    Dim d As Byte
                    d = GetDirection()
                    Dim s1 As String
                    Dim s2 As String
                    With Cells(Target.Row, Target.Column - 1)
                        s1 = LCase(.Cells(1, 1 + d).Value)
                        s2 = LCase(.Cells(1, 2 - d).Value)
                    End With
                    Dim y As Long
                    Dim b As Boolean
                    b = False
                    For y = 1 To UBound(arr, 1)
                        If LCase(arr(y, 1)) = s1 Then
                            If LCase(arr(y, 2)) = s2 Then
                                b = True
                            End If
                            Exit For
                        End If
                    Next
                    
                    If b Then
                        PrintWord d + 1
                    Else
                        Application.EnableEvents = False
                        Target.Value = Empty
                        Target.Select
                        Application.EnableEvents = True
                    End If
                
                End If
            End If
        End If
    End If
End Sub