Страницы: 1
RSS
Поиск уникальных значений по нескольким условиям за определенный период времени
 
Уважаемый форумчане, подскажите пожалуйста решение проблемы.

Есть таблица (пример). Необходимо найти кол-во уникальных значений за определенный период времени. Нужна формула, не макрос! Если это конечно возможно.
 
Добрый день.
В excel нет возможности проверить, в LO отрабатывает в соответствии с Вашим примером
=SUM(IFERROR(1/COUNTIFS($A$2:$A$21&$B$2:$B$21;$A$2:$A$21&$B$2:$B$21;$A$2:$A$21;$E2;$B$2:$B$21;">="&$E$6;$B$2:$B$21;"<="&$E$7);0))
массивная
Изменено: bigorq - 26.11.2021 13:17:02
 
К сожалению не работает... :(
 
Цитата
bigorq написал:
массивная
На это обратили внимание?
 
Рамиль Нурдинов, да, в excel не работает, во всяком случае в 2007 :( Я так понял, что не понимает в счеслимн объединенные диапазоны $A$2:$A$21&$B$2:$B$21
 
Да, конечно, выдает #ИМЯ?

Цитата
написал: в 2007  Я так понял, что не понимает в счеслимн объединенные диапазоны $A$2:$A$21&$B$2:$B$21
У меня 2016, но тоже не понимает...
 
Код
=СУММ(--(УНИК(ФИЛЬТР($A$2:$B$21;($B$2:$B$21>=$E$6)*($B$2:$B$21<=$E$7)))=E2))
 
Сохраняю файл, формула преобразуется
Код
=СУММ(--(_xlfn.UNIQUE(_xlfn._xlws.FILTER($A$2:$B$21;($B$2:$B$21>=$E$6)*($B$2:$B$21<=$E$7)))=E2))

Включаю массив
Код
{=СУММ(--(_xlfn.UNIQUE(_xlfn._xlws.FILTER($A$2:$B$21;($B$2:$B$21>=$E$6)*($B$2:$B$21<=$E$7)))=E2))} 
итог - #ИМЯ?
 
Цитата
написал:
формула преобразуется
UNIQUE из экселя 365/21
 
Ассортимент вариантов.
Массивный.
Код
=SUM(IF(($B$2:$B$30>=$E$6)*($B$2:$B$30<=$E$7)*($A$2:$A$30=E2);1/COUNTIFS($A$2:$A$30;$A$2:$A$30&"";$B$2:$B$30;$B$2:$B$30&"")))

Немассивный.
Код
=SUMPRODUCT(($B$2:$B$30>=$E$6)*($B$2:$B$30<=$E$7)*($A$2:$A$30=E2)/COUNTIFS($A$2:$A$30;$A$2:$A$30&"";$B$2:$B$30;$B$2:$B$30&""))

И снова массивный.
Код
=COUNT(0/(($B$2:$B$30>=$E$6)*($B$2:$B$30<=$E$7)*($A$2:$A$30=E2)*MATCH($A$2:$A$30&$B$2:$B$30;$A$2:$A$30&B$2:$B$30;)=ROW($1:$30)))
 
коряво (два доп.столбца) но работает
 
Такое решение устроит.? Ненужные строки скрыть.
Изменено: Василий Нисс - 28.11.2021 21:14:04
 
, Спасибо большое, все работает!!!
Есть одно "НО" - у меня слишком много значений, и бедный эксель просто умирает!!! Будем думать что с этим делать.

Всем огромное спасибо.
Страницы: 1
Наверх