Страницы: 1
RSS
Подстановка значений из другой таблицы
 
День добрый, гуру и шаманы EXCEL'я
Прошу помощи. Необходимо в столбце "D", чтобы проставилось значение "ИВАНОВА", либо "ПЕТРОВА", либо "СИДОРОВА" исходя из значений столбца "С" (номер по журналу) и закреплением  номеров за Ивановой (столбец Н3:Н17), Петровой (I2:I14) и Сидоровой соответственно
т.е. в журнале есть заявка РУ-516 это Иванова, АЧ-35 - Иванова, 22-89-Сидорова, СБ-675 Петрова
 
Здравствуйте, Базиль!
Попробуйте использовать такую формулу для ячейки D2
Код
=ЕСЛИ(ЕЧИСЛО(ПРОСМОТР(999;НАЙТИ($G$2:$G$16;$C2)));$G$1;ЕСЛИ(ЕЧИСЛО(ПРОСМОТР(999;НАЙТИ($H$2:$H$14;$C2)));$H$1;$I$1))
здесь функция НАЙТИ возвращает столбец из ошибок и чисел, соответствующих порядку вхождения каждой из литер Ивановой / Петровой в текущем проверяемом номере-по-журналу; А функция ЕЧИСЛО(ПРОСМОТР(999;НАЙТИ(...))) возвращает значение ИСТИНА, если в текущем номере-по-журналу встречается хотя бы одна из литер Ивановой / Петровой. Во всех прочих случаях функция ЕСЛИ(...;...;ЕСЛИ(...)) возвращает "Сидорову"
 
Спасибо за отклик. Попробовал. К сожалению Сидорову не цепляет :(
 
Здравствуйте, подскажите как перенести необходимые сведения из одной таблицы в другую по искомому значению. Сведения необходимо внести в одну строку. К сожелению прикрепить таблицу не могу, не грузится.  
 
Почему у Иванова "РУ-516" полный номер, а остальные только часть в справочнике указана, например, "АЧ"?
Формула массива (ввести в D2 и протянуть вниз):
=ЕСЛИ(МАКС(МУМНОЖ(СТОЛБЕЦ($G:$H);ТРАНСП(--($G$2:$H$16=$C2))));ИНДЕКС($1:$1;0;МАКС(МУМНОЖ(СТОЛБЕЦ($G:$H);ТРАНСП(--($G$2:$H$16=$C2)))));ЕСЛИ(МАКС(МУМНОЖ(СТОЛБЕЦ($G:$H);ТРАНСП(--($G$2:$H$16=ЛЕВБ($C2;ПОИСК("-";$C2)-1)))));ИНДЕКС($1:$1;0;МАКС(МУМНОЖ(СТОЛБЕЦ($G:$H);ТРАНСП(--($G$2:$H$16=ЛЕВБ($C2;ПОИСК("-";$C2)-1))))));$I$1))
Изменено: JayBhagavan - 12.04.2022 10:39:02

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
Цитата
написал:
К сожалению Сидорову не цепляет
А у меня цепляет
 
, понял, почему у меня не цепляла... Комбинацией из трех пальцев вводится :) Спасибо еще раз!!!
 
Цитата
написал:
Почему у Иванова "РУ-516" полный номер, а остальные только часть в справочнике указана, например, "АЧ"?
ну вот такой номер в журнале. ХЗ, но с давних пор именно так )
Спасибо за вариант, бум изучать.
Изменено: Basil S. - 12.04.2022 11:24:34
 
Еще пара вариантов
Код
=ВЫБОР(МАКС(ЕЧИСЛО(ПОИСК(ТЕКСТ(G$2:H$16;";;!;@");C2))*СТОЛБЕЦ(A:B))+1;I$1;G$1;H$1)
Код
=ИНДЕКС(G$1:I$1;ТЕКСТ(МАКС(ЕЧИСЛО(ПОИСК(ТЕКСТ(G$2:H$16;";;!;@");C2))*СТОЛБЕЦ(A:B)-1);"2;3;1"))
Скажи мне, кудесник, любимец ба’гов...
 
Цитата
написал:
Еще пара вариантов
Спасибо, за варианты. )
Страницы: 1
Наверх