Sub DeleteCellByVal()
    Dim r As Range, s As String, sDefaultText As String, sArr As Variant, i As Byte
    
    'sDefaultText - это текст по умолчанию в InputBox-е, т.е. текст, который появится в поле ввода
    'InputBox-а при его запуске. Этот текст мы ищем в системном реестре, если там ничего нету, то
    'функция GetSetting вернет просто пустую строку.
    'Подробнее о чтении, зиписи и удалении настроек из системного рееестра см. статью по ссылке ниже:
    'https://vk.com/@547800930-vba-sohranenie-nastroek-makrosa-v-sistemnom-reestre-i-ih-cht
    sDefaultText = GetSetting("DeleteCellByValue", "Folder1", "DefaultString")
    
    'В переменную s записываем значение с InputBox-а
    s = InputBox("Введите искомый текст", "Удаление текста", sDefaultText)
    
    'С помощью функции Trim удаляем лишние пробелы, если они были введены
    s = Application.WorksheetFunction.Trim(s)
    
    'Если в результате чистки переменной s осталась пустая строка, то выход из процедуры
    'Такое может случится, если ввести только пробел(ы)
    If s = "" Then Exit Sub
    
    'Сохраняем значение для пременной sDefaultText, текст по умолчанию в InputBox-е,
    'он будет отображен при следующем запуске макроса
    SaveSetting "DeleteCellByValue", "Folder1", "DefaultString", s
    
    'Если выделение является диапазоном ячеек, то
    If TypeName(Selection) = "Range" Then
        
        'В объектную переменную r записываем наш выделенный диапазон
        Set r = Selection
        
        'Если кол-во ячеек в диапазоне r равно 1, что может случится если пользователь ничего толком не выделил, то
        If r.Cells.Count = 1 Then
            MsgBox "Выделенна только одна ячейка!", vbQuestion, "Вы серьёзно?"
            Exit Sub 'Выход из процедуры
        End If
    Else
        Exit Sub 'Выход из процедуры, если выделение не является диапазоном ячеек
    End If
    Application.ScreenUpdating = False ' отключаем обновление экрана, для ускорения работы макроса
    
    'Если в переменной s есть пробелы, то(это значит, то там несколько слов, которые нужно удалить)
    If InStr(1, s, " ") > 0 Then
        
        'С помощью функции Split в переменную sArr записываем массив из наших слов
        sArr = Split(s, " ")
        
        'Цикл по массиву из наших слов
        For i = LBound(sArr) To UBound(sArr)
            'С помощью функции Replace, в нашем диапазоне r меняем наше слово[sArr(i)] на пустоту(удаляем)
            r.Replace sArr(i), "", 1
        Next i
    Else
        'Если в переменной s нету пробелов, то(это значит, то там только одно слово, которое нужно удалить)
        r.Replace s, "", 1
    End If
        
        'В нашем диапазоне r удаляем все пустые ячейки со сдвигом влево
        r.SpecialCells(xlCellTypeBlanks).Delete Shift:=xlToLeft
End Sub

Sub DelSet()
    On Error GoTo errmsg
    DeleteSetting "DeleteCellByValue" ', "Folder1", "DefaultString"
    Exit Sub
errmsg:
    MsgBox "Если Вы видите эту ошибку, значит, настройки уже удалены или их не было." & vbNewLine & "Ошибка №" & Err.Number & vbNewLine & Err.Description, vbOKOnly, "Очистка реестра"
End Sub