let
  src = Excel.CurrentWorkbook(){[ Name = "data" ]}[Content],
  headersLst = List.Buffer ( Table.ToColumns ( Table.FirstN ( src, 2 ) ) ),
  headersCnt = List.Count ( headersLst ),
  headers = List.Generate (
    () => [ k = 0, header = "Дата" ],
    each [k] < headersCnt,
    each [
      k = [k] + 1,
      header =
        if headersLst{k}{0} = null then
          Date.ToText ( Date.From ( headersLst{k - 1}{0} ), "MM" ) & "|" & headersLst{k}{1}
        else
          Date.ToText ( Date.From ( headersLst{k}{0} ), "MM" ) & "|" & headersLst{k}{1}
    ],
    each [header]
  ),
  rename = Table.FromColumns ( Table.ToColumns ( Table.Skip ( src, 2 ) ), headers ),
  unpivot = Table.UnpivotOtherColumns ( rename, { "Дата" }, "Атрибут", "Значение" ),
  transform = Table.FromRecords (
    Table.TransformRows (
      unpivot,
      ( r ) =>
        Record.TransformFields (
          r,
          {
            { "Дата", ( x ) => #date ( Date.Year ( Date.From ( x ) ), Number.From ( Text.BeforeDelimiter ( r[Атрибут], "|" ) ), 1 ) },
            { "Атрибут", ( x ) => Text.AfterDelimiter ( x, "|" ) }
          }
        )
    ),
    Value.Type ( unpivot )
  ),
  pivot = Table.Pivot ( transform, List.Distinct ( transform[Атрибут] ), "Атрибут", "Значение", List.Sum ),
  typed = Table.TransformColumnTypes ( pivot, { { "Дата", type date }, { "П", type number }, { "Ф", type number } } )
in
  typed