Страницы: 1
RSS
Сумма пропущенных чисел
 
Здравствуйте!

Можете подсказать формулу сложения недостающих чисел в строке, что бы эту формулу можно было вставить в ячейку и просто растянуть вниз для применения к остальным строкам.

В строке с B по I (8 ячеек) находятся в разброс числа, где в каждой ячейке одно число от 1 до 20.Допустим в строке  4 - 8 - 1 - 11 - 10 -19 - 3 - 13. А формула бы брала недостающие числа  это 2 - 5 - 6 - 7 - 9 - 12 - 14 - 15 - 16 - 17 - 18 - 20 и в ячейке  выдавала бы сумму этих чисел?
 
Виталина Филатова, не поверите, но сумма пропажи равна разнице суммы возможных 20 чисел , что просто вычислить так и тех что 8 что указаны что равно =СУММ(Bx:Ix)
По вопросам из тем форума, личку не читаю.
 
Виталина Филатова, а немного вспомнить школьную программу?
Код
a+x=b => x=b-a

Сумму от 1 до 20 можете и на калькуляторе посчитать или по сумме арифметической прогрессии.
Итого:
Код
= 210 - СУММ( B1:I1 )

P.S. Так как нет примера, то считаем, что в B1:I1 значения не повторяются.
 
Если числа уникальны и находятся в интервале от 1 до 20, то можно посчитать по формуле арифметической прогрессии и вычесть сумму известных чисел:
=(1+20)*20/2-СУММ(диапазон)
 
Спасибо вам большое за чёткость и краткость без всего этого пафоса про школу.
 
в J1
Код
=(20+1)*20/2-СУММ(B1:I1)
(результат 141)
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
Игорь, и вам спасибо!
 
Цитата
Виталина Филатова: без всего этого пафоса про школу
а мне наоборот нравится, когда тебе не просто ответ дают, но и объясняют, КАК он был получен, так что и БМВ, и surkenny — спасибо  :idea:
Во всех делах очень полезно периодически ставить знак вопроса к тому, что вы с давних пор считали не требующим доказательств (Бертран Рассел) ►Благодарности сюда◄
 
Цитата
Jack Famous написал:
КАК он был получен,
был бы пример я конечно б по Excelевски делал типа
=SUMPRODUCT(ROW(1:20))-SUM(B1:I1)
или
=SUMPRODUCT(ROW(1:20);1-COUNTIF(B1:I1;ROW(1:20)))
:D
По вопросам из тем форума, личку не читаю.
 
Для 365/2021:
=СУММ(ПОСЛЕД(20))-СУММ(B1:I1)
 
Для 365/2021: получить недостающие числа
=ТРАНСП(ФИЛЬТР(ПОСЛЕД(20);ЧАСТОТА(B1:I1;ПОСЛЕД(19))<>1))
Сумма:
Код
=СУММПРОИЗВ(СТРОКА(1:20);--НЕ(ЧАСТОТА(B1:I1;СТРОКА(1:19))))
Изменено: Тимофеев - 18.01.2022 12:15:24
 
Как вытащить все остальные числа без 365 так только первую получается:
Код
=ИНДЕКС(СТРОКА(1:20);ПОИСКПОЗ(0;ЧАСТОТА(B1:I1;СТРОКА(1:19));0))
Изменено: Тимофеев - 18.01.2022 12:57:30
 
Цитата
Тимофеев написал:
так только первую получается:
так тут то проще
=SMALL(IF(COUNTIF(B1:I1;ROW(1:20))=0;ROW(1:20));ROW(1:12))
По вопросам из тем форума, личку не читаю.
Страницы: 1
Наверх