Страницы: 1
RSS
DAX. Найти максимальную дату за прошедший период.
 
Добрый вечер уважаемые форумчане! В очередной раз прошу помочь с мерой.
Хотелось бы найти максимальную дату среди дат, которые меньше либо равны дате, на которую нужно найти эту максимальную дату ))), на скрине, надеюсь, понятнее)
У меня есть мера, но она не всегда показывает максимальную дату (в тех случаях, когда нет событий в этот день).
 
Настя_Nastya, плохо книжку читаете :)
У Вас для типа "Рабочий" на 13.06 таблица данных пуста. Таким образом выражение MAX ( 'Данные'[Дата] ) = BLANK. А какие даты меньше BLANK? :)
Поэтому создавайте календарь :)
Код
max :=
CALCULATE (
    MAX ( 'Данные'[дата время] );
    FILTER (
        ALL ( 'Calendar'[Date] );
        'Calendar'[Date] <= MAX ( 'Calendar'[Date] )
    )
)

Если календарь создадите в PQ, то там можно ограничить его сверху последней датой в данных. Или текущим днем при необходимости.
upd:
Чтобы легче было понять подобные результаты, используйте переменные. Во-первых, код можно записать гораздо лаконичнее. Во-вторых, можно быстро менять имя переменной в выводе и посмотреть промежуточные результаты. Переписал именно Вашу меру с некорректным результатом:
Код
max :=
VAR curMaxDate =
    MAX ( 'Данные'[дата] )
VAR result =
    CALCULATE ( MAX ( 'Данные'[дата время] ); 'Данные'[дата] <= curMaxDate )
RETURN
    curMaxDate
Изменено: surkenny - 19.01.2022 18:12:58
 
Настя_Nastya, если лень заморачиваться с календарем в PQ, можно еще так (вывод по последнюю дату в данных):
Код
max :=
VAR curDate =
    MAX ( 'Calendar'[Date] )
VAR maxDateInDataTable =
    MAXX ( ALL ( 'Данные' ); 'Данные'[дата] )
VAR result =
    IF (
        curDate <= maxDateInDataTable;
        CALCULATE ( MAX ( 'Данные'[дата время] ); 'Calendar'[Date] <= curDate )
    )
RETURN
    result

Либо по сегодняшний день:
Код
max :=
VAR curDate =
    MAX ( 'Calendar'[Date] )
VAR result =
    IF (
        curDate <= TODAY ();
        CALCULATE ( MAX ( 'Данные'[дата время] ); 'Calendar'[Date] <= curDate )
    )
RETURN
    result
 
surkenny, большушее спасибо!!!!
Изменено: Настя_Nastya - 19.01.2022 20:59:10
Страницы: 1
Наверх