Option Explicit

Dim fso As Object

Sub GetLastRowsFromFiles()
    Dim fileList As Variant
    fileList = ShowFileDialog()
    If Not IsEmpty(fileList) Then
        Set fso = CreateObject("Scripting.FileSystemObject")
        Dim yTxt As Long
        Dim arrTxt As Variant
        ReDim arrTxt(1 To UBound(fileList), 1 To 1)
        Dim vFile As Variant
        For Each vFile In fileList
            yTxt = yTxt + 1
            arrTxt(yTxt, 1) = GetLastRow(vFile)
        Next
        
        OutPutTxt arrTxt
    End If
End Sub

Sub OutPutTxt(arr As Variant)
    With Workbooks.Add(1)
        With .Sheets(1).Cells(1, 1).Resize(UBound(arr, 1), UBound(arr, 2))
            .Value = arr
        End With
        .Saved = True
    End With
End Sub

Function GetLastRow(ByVal sFull As String) As String
    Dim txt As String
    Dim last As String
    
    With fso.OpenTextFile(sFull, 1)
        Do
            If .AtEndOfStream Then Exit Do
            txt = .ReadLine
            If txt <> "" Then last = txt
        Loop
        .Close
    End With
    GetLastRow = last
End Function

Function ShowFileDialog() As Variant

    Dim oFD As FileDialog
    Dim x, lf As Long
    'назначаем переменной ссылку на экземпляр диалога
    Set oFD = Application.FileDialog(msoFileDialogFilePicker)
    With oFD 'используем короткое обращение к объекту
    'так же можно без oFD
    'With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = True
        .Title = "Выбрать файлы" 'заголовок окна диалога
        .Filters.Clear 'очищаем установленные ранее типы файлов
        '.Filters.Add "Excel files", "*.xls*;*.xla*", 1 'устанавливаем возможность выбора только файлов Excel
        .Filters.Add "Text files", "*.txt", 1 'добавляем возможность выбора текстовых файлов
        .Filters.Add "CSV files", "*.csv", 2 'добавляем возможность выбора текстовых файлов
        .FilterIndex = 1 'устанавливаем тип файлов по умолчанию - Text files(Текстовые файлы)
        .InitialFileName = ThisWorkbook.Path & "\"
        .InitialView = msoFileDialogViewDetails 'вид диалогового окна(доступно 9 вариантов)
        If oFD.Show = 0 Then Exit Function 'показывает диалог
        ReDim x(1 To .SelectedItems.Count)
        'цикл по коллекции выбранных в диалоге файлов
        For lf = 1 To .SelectedItems.Count
            x(lf) = .SelectedItems(lf) 'считываем полный путь к файлу
        Next
    End With
    ShowFileDialog = x
End Function

str.Charset = "UTF-8"
str.Open()
str.WriteText(Text)
str.SaveToFile "C:\UTF-8.txt", 2
str.Close()