Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Как посчитать "Прогноз выполнения плана продаж до конца месяца" в Power Bi?, Как посчитать "Прогноз выполнения плана продаж до конца месяца" в Power Bi
 
#1
21.04.2022 20:39:09
Здравствуйте.

Подскажите, пожалуйста, как можно реализовать в Power BI вот такой вот расчет:

- Кол-во продаж / Кол-во прошедших раб дней в мес * Кол-во раб дней в мес / План продаж.

Как это реализовать в Excel я понимаю, там просто надо будет каждый день указывать сколько прошло рабочих дней и кол-во рабочих дней в месяце менять из месяца в месяц. А как это реализовать в Power Bi, не понимаю. И ничего подобного не могу найти в Интернете. Только разного рода План/Факт, но это не подходит.

Заранее благодарю.
Изменено: Антон - 22.04.2022 13:46:43
 
 
 
#2
22.04.2022 06:56:00
Добрый день, советую ознакомиться с с правилами, оформления тем - тогда можете получить конкретный результат. А так... создаете календарь, в котором отмечены рабочие дни по дням. Мерой определяете текущий месяц и общее кол-во рабочих дней в этом месяце. Затем определяете, сколько прошло рабочих дней на последнюю дату фактических данных, ну а далее по вашей формуле.... сильно помогло?
 
 
 
#3
22.04.2022 10:18:03
Согласен, тему можно было и поконкретнее сформулировать. А сейчас уже её не поменять? Не могу найти такой функции.
Ваш ответ меня в любом случае направил в нужную сторон и я уже как минимум знаю куда копать. Спасибо. : )
Но мне действительно очень помогло бы, если кто-нибудь смог написать синтаксис этих мер с датами.
 
 
 
#4
22.04.2022 11:13:58
Цитата
Антон написал:
если кто-нибудь смог написать синтаксис этих мер с датами.
Ок, вот Вам пример прогноза до конца месяца по кол-ву рабочих дней из моего дашборда. Пользуйтесь:
Код
прогноз_продажи, руб. = 
VAR __last_day = CALCULATE(max(fSales[sales_datekey_DT]),all(fSales))

VAR __last_month = MAXX(FILTER(ALL('Calendar'),'Calendar'[datekey]=__last_day),'Calendar'[порядк № месяца])

VAR __salesThisMonth = CALCULATE([факт_сумма руб.], FILTER(ALL('Calendar'[порядк № месяца]),'Calendar'[порядк № месяца]=MAX('Calendar'[порядк № месяца])))

VAR __workingDaysThisMonth = COUNTROWS(FILTER(ALL('Calendar'), 'Calendar'[порядк № месяца]=__last_month && 'Calendar'[РабочийДень]="1"))

var count_days_last_month = MAXX(FILTER(ALL('Calendar'),'Calendar'[datekey]=__last_day),'Calendar'[Число])

VAR __workingDaysUpToday = COUNTROWS(FILTER(ALL('Calendar'), 'Calendar'[порядк № месяца]=__last_month && 'Calendar'[Число]<=count_days_last_month && 'Calendar'[РабочийДень]="1"))

RETURN

[факт_сумма руб.]/__workingDaysUpToday*__workingDaysThisMonth
Изменено: Vladimir Chebykin - 22.04.2022 11:15:34
 
 
 
#5
22.04.2022 13:23:58
Спасибо! Это то что мне нужно. Только я где-то допускаю ошибку и у меня получается факт выполнения плана - Факт/План.
Код
last_day = CALCULATE(MAX('AMO Сделки'[Дата]),ALL('AMO Сделки'))

last_month = MAXX(FILTER(ALL('SHD Параметры дат'),'SHD Параметры дат'[Ключ дата]=[last_day]),'SHD Параметры дат'[Номер месяца])

salesThisMonth = CALCULATE('AMO Сделки'[Количество продаж, шт.],FILTER(ALL('SHD Параметры дат'[Номер месяца]),'SHD Параметры дат'[Номер месяца]=MAX('SHD Параметры дат'[Номер месяца])))

workingDaysThisMonth = COUNTROWS(FILTER(ALL('SHD Параметры дат'),'SHD Параметры дат'[Номер месяца]=[last_month] && 'SHD Параметры дат'[Рабочий день]="Рабочий"))

count_days_last_month = MAXX(FILTER(ALL('SHD Параметры дат'),'SHD Параметры дат'[Ключ дата]=[last_day]),'SHD Параметры дат'[Дата])

workingDaysUpToday = COUNTROWS(FILTER(ALL('SHD Параметры дат'),'SHD Параметры дат'[Номер месяца]=[last_month] && 'SHD Параметры дат'[Дата]<=[count_days_last_month] && 'SHD Параметры дат'[Рабочий день]="Рабочий"))

И когда я посчитал это все:

Код
Прогноз = 'AMO Сделки'[Количество продаж, шт.]/'SHD Параметры дат'[workingDaysUpToday]*'SHD Параметры дат'[workingDaysThisMonth]/sumx('Планы продаж менеджеров','Планы продаж менеджеров'[Количество продаж])

То у меня просто получился факт выполнения:  Факт/План
Изменено: Антон - 22.04.2022 14:06:53
 
 
 
#6
22.04.2022 15:23:12
Цитата
написал:
Только я где-то допускаю ошибку и у меня получается факт выполнения плана - Факт/План.
На самом деле все работает. ))) Это я просто в финальном расчете вместо salesThisMonth поставил общий факт.))))

Вот так надо было:
Код
'SHD Параметры дат'[salesThisMonth]/'SHD Параметры дат'[workingDaysUpToday]*'SHD Параметры дат'[workingDaysThisMonth]/sumx('Планы продаж менеджеров','Планы продаж менеджеров'[Количество продаж])

Цитата
написал:
Ок, вот Вам пример прогноза до конца месяца по кол-ву рабочих дней из моего дашборда. Пользуйтесь:
Еще раз большое спасибо!

Изменено: Антон - 22.04.2022 15:23:41
 
 
 
Страницы: 1
Наверх