Option Explicit

Dim fso As Object

Sub СобратьФайлы()
    Dim arrFiles As Variant
    arrFiles = ShowFileDialog()
    If IsEmpty(arrFiles) Then Exit Sub
    Dim Application_Calculation As Long
    Application_Calculation = Application.Calculation
    Application.Calculation = xlCalculationManual
     
    Set fso = CreateObject("Scripting.FileSystemObject")
    Dim wb As Workbook
    Set wb = Workbooks.Add(1)
    Dim rOut As Range
    Set rOut = wb.Sheets(1).Cells(1, 1)
    Dim vFile As Variant
    For Each vFile In arrFiles
        JobFile vFile, rOut
    Next
     
    Application.Calculation = Application_Calculation
    wb.Saved = True
End Sub
 
Sub JobFile(ByVal sFile As String, rOut As Range)
    With fso.OpenTextFile(sFile, 1)
        rOut.Value = .ReadAll
        .Close
    End With
    Set rOut = rOut.Cells(2, 1)
End Sub
 
Function ShowFileDialog() As Variant
    Dim oFD As FileDialog
    Dim lf As Long
    'назначаем переменной ссылку на экземпляр диалога
    Set oFD = Application.FileDialog(msoFileDialogFilePicker)
    With oFD 'используем короткое обращение к объекту
    'так же можно без oFD
    'With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = True
        .Title = "Выбрать файлы" 'заголовок окна диалога
        .Filters.Clear 'очищаем установленные ранее типы файлов
        '.Filters.Add "Excel files", "*.xls*;*.xla*", 1 'устанавливаем возможность выбора только файлов Excel
        .Filters.Add "Text files", "*.txt", 1 'добавляем возможность выбора текстовых файлов
        .FilterIndex = 1 'устанавливаем тип файлов по умолчанию - Text files(Текстовые файлы)
        .InitialFileName = ThisWorkbook.Path & "\"
        .InitialView = msoFileDialogViewDetails 'вид диалогового окна(доступно 9 вариантов)
        If oFD.Show = 0 Then Exit Function 'показывает диалог
        'цикл по коллекции выбранных в диалоге файлов
        Dim arr As Variant
        ReDim arr(1 To .SelectedItems.Count)
        For lf = 1 To .SelectedItems.Count
            arr(lf) = .SelectedItems(lf) 'считываем полный путь к файлу
        Next
        ShowFileDialog = arr
    End With
End Function

=ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(A1;"/";"</i><i>")&"</i></j>";"//i[1]")
=ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(A1;".";"</i><i>")&"</i></j>";"//i[2]")
=ПСТР(ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(A1;"рождения.";"</i><i>")&"</i></j>";"//i[2]");1;10)