Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Среднее значение результатов за предыдущие три месяца
 
#1
26.05.2022 12:54:15
Всем Привет!
Уже долго ломаю голову, но никак не могу хорошо решить задачку, кроме как увеличить формулу в два раза и разбить ее на разность суммы и количества.
Мне необходимо определить среднее значение за предыдущие три месяца.
Для этого я использую формулу:
Код
=СРЗНАЧ(
ЕСЛИОШИБКА(ИНДЕКС(C2:C5;ПОИСКПОЗ($L$3&$M$3;$A$2:$A$5&$B$2:$B$5;0));"");
ЕСЛИОШИБКА(ИНДЕКС(C2:C5;ПОИСКПОЗ($L$4&$M$4;$A$2:$A$5&$B$2:$B$5;0));"");
ЕСЛИОШИБКА(ИНДЕКС(C2:C5;ПОИСКПОЗ($L$5&$M$5;$A$2:$A$5&$B$2:$B$5;0));""))

И она работает корректно если для каждого из месяцев есть данные, но бывает такое, что по некоторым месяцам нет данных и формула выдает ошибку.
Изменено: evgeniygeo - 26.05.2022 12:54:49
 
 
 
#2
26.05.2022 13:08:31
Хай.
СРЗНАЧ не может оперировать с строками. Если по какому-либо месяцу нет данных, то выдается строка "". Она порождает ошибку при вычислении СРЗНАЧ.
Может использовать 0 в ЕСЛИОШИБКА?
Кому решение нужно - тот пример и рисует.
 
 
 
#3
26.05.2022 13:19:08
Код
=СУММ((A2:A5&B2:B5=ТРАНСП(L3:L5&M3:M5))*C2:C5)/СЧЁТ(1/(A2:A5&B2:B5=ТРАНСП(L3:L5&M3:M5)))

Формула массива. Вводится одновременным нажатием Контрл Шифт Ентер
Или без серой доптаблицы
Код
=СУММПРОИЗВ(C2:C5*(A2:A5=ГОД(ДАТАМЕС(H2&-G2;-СТОЛБЕЦ(A:C))))*(B2:B5=МЕСЯЦ(ДАТАМЕС(H2&-G2;-СТОЛБЕЦ(A:C)))))/СУММПРОИЗВ((A2:A5=ГОД(ДАТАМЕС(H2&-G2;-СТОЛБЕЦ(A:C))))*(B2:B5=МЕСЯЦ(ДАТАМЕС(H2&-G2;-СТОЛБЕЦ(A:C)))))
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#4
26.05.2022 13:19:34
Попробуйте использовать такую конструкцию
Код
=СУММПРОИЗВ($A$2:$A$5*($B$2:$B$5=$H$2-{0;1;2})*$C$2:$C$5)/СУММПРОИЗВ($A$2:$A$5*($B$2:$B$5=$H$2-{0;1;2}))
хотя возможно, для её работы может потребоваться офис 365
 
 
 
#5
26.05.2022 13:23:55
evgeniygeo, а у Вас в таблице только 2022 год?
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#6
26.05.2022 13:53:52
Если офис выше 2019 то можно так
Код
=СРЗНАЧ(ФИЛЬТР(C2:C5;НЕ(ЕНД(ПОИСКПОЗ(A2:A5&B2:B5;L3:L5&M3:M5;0)))))
Цитата
_Boroda_ написал:
а у Вас в таблице только 2022 год?
если только 2022, то можно покороче
Код
=СРЗНАЧ(ФИЛЬТР(C2:C5;СЧЁТЕСЛИ(M3:M5;B2:B5)))
 
 
 
#7
27.05.2022 06:14:02
Всем большое спасибо за участие!

Да, только тогда результат будет неверным.
Цитата
Пытливый написал:
Может использовать 0 в ЕСЛИОШИБКА?
У меня 365, но при появлении частичных данных за предыдущий год она не работает корректно
Цитата
IKor написал:
Попробуйте использовать такую конструкцию
Есть и предыдущие года в том числе, но не по всем месяцам, но Ваш вариант работает при этом
Цитата
_Boroda_ написал:
а у Вас в таблице только 2022 год?
Супер, это прям лучший вариант  :)
Цитата
Msi2102 написал:
Если офис выше 2019 то можно так
Изменено: evgeniygeo - 27.05.2022 06:15:05
 
 
 
#8
27.05.2022 09:19:42
Цитата
evgeniygeo написал:
но Ваш вариант работает при этом
У меня да, работает, это я больше для IKor написал ))))
Скажи мне, кудесник, любимец ба’гов...
 
 
 
Страницы: 1
Наверх