Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
В формулу Поиск добавить второе условие, В ячейке искать из 2х значений
 
#1
15.06.2022 22:21:18
Помогите, пожалуйста, дополнить формулу
Из ячейки возвращается значение по формуле поиск ПСТР(I2;ПОИСК("S*";I2);1) - тут все хорошо
Как к формуле добавить, чтобы она срабатывала также если в значении не только S, но и V (интересует только первое соответствующее значение S или V)
Добавляла в разных вариациях ИЛИ и дублировала формулу с Поиском, не получалось.
Спасибо.
 
 
 
#2
16.06.2022 00:10:01
Код
=MID(I2;AGGREGATE(14;6;SEARCH({"S*"\"V*"};I2);1);1)
 
 
 
#3
16.06.2022 09:54:03
Или так:
Код
=ПСТР(I2;МИН(ЕСЛИОШИБКА(ПОИСК({"S";"V"};I2);999));1)
Изменено: Msi2102 - 16.06.2022 10:10:29
 
 
 
#4
16.06.2022 10:06:46
Цитата
memo написал:
=MID(I2;AGGREGATE(14;6;SEARCH({"S*""V*"};I2);1);1)
memo, Наверное в агрегате номер функции должен быть 15, вместо 14, нужно первое вхождение
 
 
 
#5
16.06.2022 10:24:02
Msi2102, Тут без разницы, в каждой ячейке ищется или одно значение или другое. Если одно найдено, то второе условие выдает ошибку, которую агрегат игнорирует.
 
 
 
#6
16.06.2022 10:58:56
Цитата
memo написал:
или одно значение или другое
Именно если два значения то найдет последнее, а нужно первое
 
 
 
#7
16.06.2022 11:29:07
Спасибо! И первый и второй вариант отличные, буду использовать. Получается, агрегат с 14 наибольшим будет брать первое попавшееся значение из поиска?
Если не затруднит, буду признательна за ответ.
Но все равно огромное спасибо)
 
 
 
#8
16.06.2022 12:17:18
Цитата
Msi2102 написал:
нужно первое вхождение
Т.е. нужно то, которое из двух стоит раньше? Тогда, да, 14 нужно исправить на 15.
Цитата
ольга макарова написал:
Получается, агрегат с 14 наибольшим будет брать первое попавшееся значение из поиска?
Да, агрегат с 14 будет возвращать максимальную позицию значения S или V. При этом все последующие вхождения S или V будут проигнорированны, поскольку функция ПОИСК выдает только первое вхождение.
Изменено: memo - 16.06.2022 12:33:56
 
 
 
#9
16.06.2022 14:17:48
Спасибо за объяснения, да, на 15 исправила.
 
 
 
#10
16.06.2022 14:42:47
Ну и напоследок вариант с выводом нескольких вхождений:
Код
=IFERROR(MID($I2;AGGREGATE(15;6;FIND(CHAR(1);SUBSTITUTE($I2;{"S";"V"};CHAR(1);{1\2\3}));COLUMNS($I2:I2));1);"-")

Формула найдет до трех вхождений. Можно больше, нужно только увеличить последовательность {1\2\3\.. и т.д}
 
 
 
Страницы: 1
Наверх