Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Формула из 128-131 сделать 128, 129, 130, 131 (отдельно в каждой ячейке)
 
#1
22.06.2022 01:42:06
Подскажите, пожалуйста, как можно распределить диапазон страниц формата "128-131" (это в одной ячейке) на 128, 129, 130, 131 (отдельно в каждой ячейке)
Или хотя бы какие функции посмотреть примеры.. поискал по форуму разные формулы пробовал сделать, за 4 часа пока не получилось..
Буду благодарен любой подсказке.
 
 
 
#2
22.06.2022 02:14:30
Ну, как вариант.
Если значения в А1 то в вставляете формулу в В1 и тянете вправо.
Код
=IFERROR(AGGREGATE(15;6;ROW(INDEX($A:$A;LEFT($A1;SEARCH("-";$A1)-1)):INDEX($A:$A;RIGHT($A1;LEN($A1)-SEARCH("-";$A1))));COLUMNS($B1:B1));"")

Не забудьте перевести формулу если офис русский.
 
 
 
#3
22.06.2022 06:17:22
Николай Р,
ну и мой вариант:
так
Код
=ТРАНСП(СТРОКА(ДВССЫЛ("A"&ЛЕВСИМВ($A1;ПОИСК("-";$A1)-1)&":A"&ПРАВСИМВ($A1;ДЛСТР($A1)-ПОИСК("-";$A1)))))

или так
Код
=СТРОКА(ДВССЫЛ("A"&ЛЕВСИМВ($A1;ПОИСК("-";$A1)-1)&":A"&ПРАВСИМВ($A1;ДЛСТР($A1)-ПОИСК("-";$A1))))
 
 
 
#4
22.06.2022 08:15:06
Код
=ПОСЛЕД(1;
ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(A1;"-";"</i><i>")&"</i></j>";"//i[2]")-
ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(A1;"-";"</i><i>")&"</i></j>";"//i[1]")+1;
ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(A1;"-";"</i><i>")&"</i></j>";"//i[1]");
1)
 
 
 
#5
22.06.2022 08:20:04
Николай Р, Может всё таки файлик с примером приложите
 
 
 
#6
22.06.2022 09:21:14
evgeniygeo,
По-моему такой вариант тоже должен работать (формула-массива!)
Код
=СТРОКА(ДВССЫЛ(ПОДСТАВИТЬ($A$1;"-";":")))
Изменено: IKor - 22.06.2022 09:22:00
 
 
 
#7
22.06.2022 09:40:38
Как вставлять эти формулы, чтобы работали?
У меня только формула от  memo работает, в переводе через указанный им сервис
 
 
 
#8
22.06.2022 09:49:42
Ctrl+Shift+Enter
 
 
 
#9
22.06.2022 09:52:37
nilske,
В столбце В надо выделить строки от В1 до В8, затем в адресную строку вставить формулу, скажем из поста №6 и нажать ctrl+shift+enter. Получится непрерывный массив. Кстати в новых офисах эту процедуру можно не выполнять формула сама динамически (SPILL formula) "протянет" значения.
Изменено: memo - 22.06.2022 09:55:29
 
 
 
#10
22.06.2022 10:30:49
IKor,
Ваш лучше))))
 
 
 
#11
22.06.2022 10:35:27
Цитата
написал:
Ну, как вариант.
Если значения в А1 то в вставляете формулу в В1 и тянете вправо.
Код
    [URL=#]?[/URL]       1      =IFERROR(AGGREGATE(15;6;ROW(INDEX($A:$A;LEFT($A1;SEARCH(  "-"  ;$A1)-1)):INDEX($A:$A;RIGHT($A1;LEN($A1)-SEARCH(  "-"  ;$A1))));COLUMNS($B1:B1));  ""  )  
 
Не забудьте  перевести  формулу если офис русский.
Ураа!! Этот вариант сразу получился!! спасибо большое!!!
Ребята, всем огромнейшее спасибо, минимум 3 способа уже получились!!  Рад, что сразу нашёл вас и пришёл на этот форум))  
Изменено: Николай Р - 24.06.2022 16:49:29
 
 
 
Страницы: 1
Наверх