Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Уникальный список по двум столбцам
 
#1
26.07.2022 22:04:37
Добрый день!
Подскажите как получить уникальный список формулами по двум столбцам, уже всю голову сломал и не получается. Т.е. первый столбец может быть с повторами данных, но второй столбец напротив разные данные поэтому стока уникальная если первый и второй одинаковы тогда повтор и его в список брать не надо. Приложил пример.
 
 
 
#2
26.07.2022 23:23:07
Скопировать 2 колонки  на новый лист, меню: "Данные" ->"Удаление дубликатов" и скопировать результат обратно. Такой вариант не подходит?
 
 
 
#3
26.07.2022 23:26:11
Нет, нужна формула без дополнительного столбца
 
 
 
#4
27.07.2022 06:01:34
noobastik,
самый быстрый вариант, но нужен 365 офис:
Код
=УНИК(B3:C12)

вариант с доп столбцом:
Код
=ЕСЛИ(СЧЁТЕСЛИМН($B$2:B3;B3;$C$2:C3;C3)=1;МАКС($D$2:D2)+1;"ПОВТОР")
=ИНДЕКС(B$3:B$12;ПОИСКПОЗ($G3;$D$3:$D$12;0))
Изменено: evgeniygeo - 27.07.2022 06:04:16
 
 
 
#5
27.07.2022 06:25:37
ввести в любую ячейку третьей строки и протянуть вправо и вниз:
=ЕСЛИОШИБКА(ИНДЕКС(B:B;АГРЕГАТ(15;6;СТРОКА($A$3:$A$12)/(СЧЁТЕСЛИМН(СМЕЩ($B$3:$B$12;0;0;СТРОКА($B$3:$B$12)-СТРОКА($2:$2));$B$3:$B$12;СМЕЩ($C$3:$C$12;0;0;СТРОКА($C$3:$C$12)-СТРОКА($2:$2));$C$3:$C$12)=1);$A3));"")

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#6
27.07.2022 09:09:03
В Вашем случае необходимо вывести уникаты по столбцу Наименование и затем по нему вывести значения столбца Код.
Код
=IFERROR(INDEX(C$3:C$12;MATCH(TRUE;INDEX(COUNTIF(N$2:N2;C$3:C$12)=0;0);0));"")
Код
=IFERROR(INDEX(B3:B12;MATCH(N3;C3:C12;0));"")
 
 
 
#7
27.07.2022 10:48:13
И еще вариант. В L3 вправо и вниз.
Код
=INDEX(B$3:B$15;MATCH(TRUE;INDEX((COUNTIFS($L$2:$L2;$B$3:$B$15;$M$2:$M2;$C$3:$C$15)=0););0))

С обработкой пустых строк:
Код
=IFERROR(INDEX(B$3:B$15;MATCH(1;INDEX((COUNTIFS($L$2:$L2;$B$3:$B$15;$M$2:$M2;$C$3:$C$15)=0)/($B$3:$B$15>0)/($C$3:$C$15>0););0));"")
Изменено: memo - 27.07.2022 10:55:46
 
 
 
#8
27.07.2022 11:07:15
Цитата
написал:
нужна формула без дополнительного столбца
А стоит ли самому себе создавать трудности, чтобы затем героически преодолевать?
Склейте данные из обоих столбцов (можно через разделитель) в дополнительном - и уже для него ищите уникальные значения любым удобным способом.
 
 
 
#9
27.07.2022 11:32:37
И еще до кучи ))
Код
=ПРОСМОТР(;СЧЁТЕСЛИМН($P$2:$P2;$B$3:$B$12;$Q$2:$Q2;$C$3:$C$12);B$3:B$12)
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#10
27.07.2022 12:30:36
Цитата
_Boroda_ написал:
И еще до кучи ))
И ещё (офис 2019 и выше)
Код
=ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(ОБЪЕДИНИТЬ("|";1;C3:C12);"|";"</s><s>")&"</s></t>";"//s[not(preceding::*=.)]")
 
 
 
#11
27.07.2022 20:50:31
Нифига себе, сколько вариантов, спасибо всем. Вот я балда, нужно было начинать со второго столбца и потом уже на первый. Всем спасибо буду пробовать варианты разные
Код
=ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(ОБЪЕДИНИТЬ("|";1;C3:C12);"|";"</s><s>")&"</s></t>";"//s[not(preceding::*=.)]")
Прям экзотика какая-то  :D  
 
 
 
Страницы: 1
Наверх