Application.Caller

Sub CopySheets()
    Dim vFullPath As Variant, vFile As Variant, wbTemp As Workbook, wbThis As Workbook
    Dim arrSheetsNames As Variant, vSheetName As Variant
    
    'укажите названия листов, как в этом примере
    arrSheetsNames = Array("Лист1", "Лист2", "Лист3")
    
    'проверка на наличие указанных листов в текущем файле
    Set wbThis = ThisWorkbook
    For Each vSheetName In arrSheetsNames
        If SheetExists(vSheetName) = False Then
            MsgBox "В файле " & wbThis.Name & " отсутствует лист: " & vSheetName, vbExclamation, "Внимание"
            Exit Sub
        End If
    Next vSheetName
    
    'диалог выбора второго файла, куда будем копировать данные
    vFullPath = Application.GetOpenFilename("Файлы Excel,*.xls*", 1, "Выберите файл", , False)
    If Not IsArray(vFullPath) Then
        If vFullPath = False Then Exit Sub
    End If
    
    Application.ScreenUpdating = False
    
    'открываем указанный файл
    Set wbTemp = Workbooks.Open(vFullPath, UpdateLinks:=False, ReadOnly:=False)
    
    'цикл по указанным листам
    For Each vSheetName In arrSheetsNames
        'проверяем есть ли такой лист в открытом файле
        If SheetExists(vSheetName) = False Then
            MsgBox "В файле " & wbTemp.Name & " отсутствует лист: " & vSheetName, vbExclamation, "Внимание"
            Exit Sub
        End If
        'очищаем старые данные на листе
        wbTemp.Worksheets(vSheetName).Cells.Clear
        'копируем данные из одного файла в другой
        wbThis.Worksheets(vSheetName).UsedRange.Copy Destination:=wbTemp.Worksheets(vSheetName).Range("A1")
    Next vSheetName

    'закрываем файл
    wbTemp.Close SaveChanges:=True
    
    Application.ScreenUpdating = True
    
    MsgBox "Данные скопированы!", vbInformation, "Конец"
End Sub

Private Function SheetExists(ByVal sName As String) As Boolean
    On Error Resume Next
    With Worksheets(CStr(sName)): End With
    SheetExists = (Err = 0)
    Err.Clear
End Function