Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Подтянуть цену по артикулу
 
#1
16.11.2023 15:02:59
Приветствую, товарищи! Скорее всего это банальная тема для Вас, но не могу решить задачку.

Есть лист "Задание" . Каждому артикулу нужно присвоить цену из листа "Артикулы Цены", в котором указана цена и список артикулов.
Я пробовал ВПР и ИНДЕКС + ПОИСКПОЗ в их простых вариантах, но у меня ничего не получилось.

Буду благодарен за помощь!
 
 
 
#2
16.11.2023 15:13:31
Сделал на одном листе, сейчас придут гуру и сделают качественно.
 
 
 
#3
16.11.2023 15:16:28
Код
=ЕСЛИ(ЛЕВСИМВ(B2;1)="U";'Артикулы Цены'!$B$2;ЕСЛИ(ЛЕВСИМВ(B2;1)="Ш";'Артикулы Цены'!$C$2;'Артикулы Цены'!$D$2))
Изменено: nilske - 16.11.2023 15:19:55
 
 
 
#4
16.11.2023 15:19:52
Формула массива:
=МАКС(ЕСЛИ(ЕЧИСЛО(ПОИСК(B2;'Артикулы Цены'!$B$3:$D$378));--'Артикулы Цены'!$B$2:$D$2;))
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
 
 
#5
16.11.2023 15:21:11
Код
=ЕСЛИОШИБКА(ИНДЕКС('Артикулы Цены'!$A$2:$D$2;1/(1/МАКС((B2='Артикулы Цены'!$B$3:$D$378)*СТОЛБЕЦ('Артикулы Цены'!$B$3:$D$378))));"")
Формула массива.
 
 
 
#6
16.11.2023 15:22:12
Код
=МАКС(ЕСЛИОШИБКА(ПОИСК(B2;'Артикулы Цены'!$B$1:$D$1000)*'Артикулы Цены'!$B$2:$D$2;0))
 
 
 
#7
16.11.2023 15:48:53
Код
=СУММПРОИЗВ((B2='Артикулы Цены'!B$3:D$378)*'Артикулы Цены'!B$2:D$2)
В 'Артикулы Цены'!B$2:D$2 цены текстом заменены на цены числами.
Формат ячеек на листе "Задание" 0,00;;"-"
Алексей М.
 
 
 
#8
16.11.2023 15:54:12
Или так
Код
=МАКС((B2='Артикулы Цены'!$B$3:$D$378)*'Артикулы Цены'!$B$2:$D$2)
Изменено: Msi2102 - 16.11.2023 15:56:19
 
 
 
#9
16.11.2023 15:56:32
Msi2102, так формула массивная получится
Алексей М.
 
 
 
#10
16.11.2023 15:57:23
Цитата
АlехМ написал:
Msi2102 , так формула массивная получится
Согласен, но если в двух столбцах будет одно и тоже наименование, то выберется максимальное, а при =СУММПРОИЗВ они просуммируются  :D
Изменено: Msi2102 - 16.11.2023 16:00:18
 
 
 
#11
16.11.2023 16:03:24
Msi2102, я бы купил наименование подешевле или сразу оба  :)  
Алексей М.
 
 
 
#12
16.11.2023 16:05:45
Цитата
АlехМ написал:
я бы купил наименование подешевле
Так это смотря с какой стороны посмотреть, со стороны продавца, лучше подороже :)
 
 
 
#13
16.11.2023 16:34:10
Если дружите с power query, то через  отменить свертывание столбцов, а потом обычным ВПР.
 
 
 
#14
16.11.2023 17:24:50
Цитата
Сергей Титов написал:
а потом обычным ВПР.
а PQ этого не может что-ли? Кстати, файл прикрепили оригинальный, без каких либо правок.
Пришелец-прораб.
 
 
 
#15
16.11.2023 17:50:53
PQ
Код
let
    excel = (tbl_name) => Excel.CurrentWorkbook(){[Name=tbl_name]}[Content],
    price_list = Table.ToColumns(excel("price_list")),
    sku = excel("sku"),
    pl = Record.Combine(
            List.Transform(
                price_list,
                (x) => 
                    [price = Number.FromText(x{0}, "ru-RU"),
                    items = List.RemoveNulls(List.RemoveFirstN(x, 1)),
                    rec = Record.FromList(List.Repeat({price}, List.Count(items)), items)][rec]
            )
    ),
    price = Table.AddColumn(sku, "Цена", (x) => Record.FieldOrDefault(pl, x[Артикул], "чота не нашла я"))
in
    price
Пришелец-прораб.
 
 
 
#16
18.11.2023 15:13:19
Товарищи, сколько вариаций! Сел все пробовать. Огромное спасибо
 
 
 
Страницы: 1
Наверх