Страницы: 1
RSS
Сократить формулу с многократно повторяющейся частью условий
 
Прошу помочь в написании формулы. В таблице выделено ячейка красным цветом.
Код
=ЕСЛИ(И(ИЛИ(H8=$L$1;H8=$L$2;H8=$L$3);A8<4;I8>60);"3";
ЕСЛИ(И(ИЛИ(H8=$L$1;H8=$L$2;H8=$L$3);A8<4;I8>45;I8<=60);"2";
ЕСЛИ(И(ИЛИ(H8=$L$1;H8=$L$2;H8=$L$3);A8<4;I8>30;I8<=45);"1,5";
ЕСЛИ(И(ИЛИ(H8=$L$1;H8=$L$2;H8=$L$3);A8<4;I8<=30);"1";""))))
По этим условиям, написать формулу. Не такую громоздкую.
Спасибо
Изменено: Sanja - 16.05.2024 07:27:13 (Изменение Названия Темы)
 
Для того, что-бы помочь Вам с формулой, нужно знать ЧТО она считает.
Как только сформулируете эту мысль, так сразу же создайте новую тему с соответствующим названием. Закрыто
Согласие есть продукт при полном непротивлении сторон
 
kristina S,
Во тут разгорелись нешуточные споры) Заодно и решение есть
Согласие есть продукт при полном непротивлении сторон
 
=IF(OR(H9=$L$1:$L$3)*(A9<4);LOOKUP(I9;{0;31;41;61};{1;1,5;2;3});"")
=IF(OR(H9=$L$1:$L$3)*(A9<4);LOOKUP(-I9;-{999;60;40;30};{3;2;1,5;1});"")
=IF(OR(H9=$L$1:$L$3)*(A9<4);-VLOOKUP(-I9;-{999\3;60\2;40\1,5;30\1};2);"")

999 - наверно не появится но всеж корректнее его убрать
=IF(OR(H9=$L$1:$L$3)*(A9<4);IFERROR(LOOKUP(-I9;-{60;40;30};{2;1,5;1});3);"")
=IF(OR(H9=$L$1:$L$3)*(A9<4);IFERROR(2,5-MATCH(-I9;-{60;40;30})/2;3);"")
=IF(OR(H9=$L$1:$L$3)*(A9<4);IFERROR(2,5-MATCH(I9;{60;40;30};-1)/2;3);"")
Изменено: БМВ - 16.05.2024 11:15:11
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал: {0;31;41;61}
Михаил,  доброе утро!
Это если только целые числа, а не 30,5 например. Хотя пример учебный, конечно.
P.S. -{999;60;40;30} - красота! 👍
Формулы массива в старых версиях
Изменено: ZVI - 16.05.2024 08:41:45
 
файл набросал вчера. видимо похоже на решение БМВ, только без{}
 
Доброе утро! Красота, хорошее утро! Спасибо за решение. Всем удачного дня.
 
Формулы небольшие, красивые. А моя огромная каракатица.
 
Вдогонку дискуссии...
Лично у меня при прочтении названия темы первая ассоциация была с LAMBDA - новая суперфункция Excel - но, к сожалению, у меня в MSExcel-2021 она по-прежнему не работает :(
 
Цитата
ZVI написал:
Это если только целые числа, а не 30,5 например.
ну я на сущьность смотрел этих данных и там дробное маловероятно, но потом решил добить, подправил в дороге с телефона :-)

Самый корректный вариант всеж =IF(OR(H9=$L$1:$L$3)*(A9<4);IFERROR(LOOKUP(-I9;-{60;40;30};{2;1,5;1});3);"")

Все указанные числа соотвеncnвуют тому что есть.
По вопросам из тем форума, личку не читаю.
Страницы: 1
Наверх