Sub main()
    Dim a&(), b&(), i&, clm&, rws&, m&, n&, nMin&, nMax&, p&, txt$
    n = 20 'выборка из 20 чисел
    nMin = 1 'минимальная выборка
    nMax = 5 'максимальная выборка
    If nMin < 1 Then nMin = 1 'проверка на правильность значений
    If nMax > n Then nMax = n
      
    rws = 1 ' начальная строка для вывода
    clm = 1 'начальный столбец для вывода
    Cells(rws, clm).CurrentRegion.ClearContents 'очищаем диапазон вывода
    
    For m = nMin To nMax 'перебираем все выборки
        ReDim a&(1 To m)
        For i = 1 To m: a(i) = i: Next i 'начальная расстановка
        If m = n Then p = 1 Else p = m
        Do 'перебираем все сочетания m из n
            'здесь нужно сделать проверку, если очерендная генерация нам подходит
            If True Then 'вместо True должно быть условие при котороам будем запоминать генерацию
                txt = ""
                For i = 1 To m 'генерируем строку для вывода
                    txt = txt & IIf(txt = "", "", ", ") & a(i)
                Next i
                Cells(rws, clm) = txt 'сохраняем строку с индексами
                rws = rws + 1
                If rws > Rows.Count Then rws = 1: clm = clm + 1
            End If
            If a(m) = n Then p = p - 1 Else p = m
            If p Then
                For i = m To p Step -1
                    a(i) = a(p) + i - p + 1
                Next i
            End If
        Loop While p
    Next m
End Sub