Страницы: 1
RSS
Убрать все символы из ячейки до определенного знака (формула)
 
Кто знает нужна формула что бы убрать из ячейки весь текст который расположен слева от заданного знака.
например текст в ячейке "opic_new&FID=1" как убрать все включая знак "&" и оставить только "FID=1"
 
Код
=ПСТР(A1;ПОИСК("&";A1)+1;99)
 
=ЗАМЕНИТЬ(A1;1;ПОИСК("&";A1);)
 
Проблема похожая, нужно удалить весь текст до значения <p  после значения много текста, Excel 2013.
Изменено: bizzon - 28.11.2016 16:27:24
 
Формула похожая. Вы пробовали применять?
Цитата
убрать из ячейки весь текст который расположен слева...  все включая знак "&"...
удалить весь текст до значения <p
Большая разница?
ПОИСК("<p";A1)-1
 
Похоже, Вы применили часть формулы, в которой я показал, что нужно исправить. Целая формула - в сообщениях №2 и №3
 
=ЗАМЕНИТЬ(A1;1;ПОИСК("<p";A1)-1) использовал эту, все равно пишет мало аргументов
https://yadi.sk/i/TnvpAshxzgFDN вот файл
Изменено: bizzon - 28.11.2016 17:31:51
 
=ЗАМЕНИТЬ(A2;1;ПОИСК("<p";A2)-1;)
 
огромное спасибо
 
Добрый день.
Прошу помощи, нужно всё то же самое, только чтобы Excel удалял текст перед 3 русскими буквами.
То есть, что бы Excel находил подряд 3 русские буквы и удалял всё перед первой русской буквой.
Пример во вложенииПример.xlsx (9.12 КБ)
 
Пробуйте
Код
=ЕСЛИОШИБКА(ПСТР(A2;ПОИСК(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A2;" ";"</s><s>")&"</s></t>";"//s[translate(.,'абвгдеёжзийклмнопрстуфхцчшщъыьэюя','')!=.][translate(.,'1234567890abcdefghijklmnopqrstuvwxyz','')=.][string-length()>3]");A2);999);"")
Изменено: Msi2102 - 07.06.2023 15:47:12
 
Еще вариант для пробы )
=ЕСЛИОШИБКА(ПСТР(A2;МИН(ЕСЛИОШИБКА(ПОИСК(" ??"&СИМВОЛ(СТРОКА($224:$255));A2)+1;""));999);"")
 
Цитата
написал:
Пробуйте
Да, но некоторые строки почему-то не читает, я добавил в пример пару строк, где формула не работает.
 
Павел с Востока, А если так:
Патрубок A2а1R22110919220 Патрубок воздушного фильтра Газель дв.
 
Павел, утёс СИМВОЛ(ЕСЛИОШИБКА(СТРОКА($224:$255)*ЧАСТОТА(СТРОКА($224:$255);СТРОКА($224:$255));184))
Gefest добавьте АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ
Изменено: Тимофеев - 07.06.2023 15:59:10
 
Цитата
Тимофеев написал:
добавьте АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ
Вот так
Код
=ЕСЛИОШИБКА(ПСТР(A2;ПОИСК(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A2;" ";"</s><s>")&"</s></t>";"//s[translate(.,'абвгдеёжзийклмнопрстуфхцчшщъыьэюяАБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ','')!=.][translate(.,'1234567890abcdefghijklmnopqrstuvwxyz','')=.][string-length()>3]");A2);999);"")
 
Код
=ЕСЛИОШИБКА(ЗАМЕНИТЬ(A2;1;
ПОИСК("111";СЦЕП((КОДСИМВ(ПСТР(СТРОЧН(A2);СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A2)));1))>=224)+
(КОДСИМВ(ПСТР(СТРОЧН(A2);
СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A2)));1))=184)))-1;"");"")
 
Цитата
Msi2102,  Патрубок A2а1R22110919220 Патрубок воздушного фильтра Газель дв.
Я ж сказал для пробы )
Причем все варианты в примере считает и во втором тоже, кроме предпоследней строки где аглицкие маскируются русскими
Цитата
Тимофеев,  Павел, утёс
Кого утёс? ))
 
Всех благодарю за помощь, оба варианта оказались рабочими для меня.
 
Не понял, а зачем искать три русские буквы подряд? В вашем примере достаточно найти первую русскую букву...
 
Цитата
написал:
Не понял, а зачем искать три русские буквы подряд? В вашем примере достаточно найти первую русскую букву...
Что бы находить целые слова исключая предлоги и просто случайные одиночные буквы после английского текста, в примере буквально несколько позиций из ~500.000 строк.
 
Еще вариант без новых функций и если следовать строгой букве закона условий
=ЕСЛИОШИБКА(ПСТР(A2;ПОИСК(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(" "&A2;" ";ПОВТОР(" ";99));ПОИСКПОЗ(3;МУМНОЖ(--(ABS(КОДСИМВ(ПСТР(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(" "&ПОДСТАВИТЬ(СТРОЧН(A2);"ё";"е");" ";ПОВТОР(" ";99));СТРОКА($1:$99)*99;99))&"zzz";{1;2;3};1))-239,5)<16);{1:1:1});0)*99;99));A2);999);"")
Страницы: 1
Наверх