Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Печать скрытых листов при условие заполненой ячейки
 
#1
13.05.2013 20:03:48
Всем доброго вечера!
Есть два макроса(нашёл на форуме):
-первый печатает только те листы книги в которых ячейка А1 не пуста или не равна нулю, но если листы скрыть то макрос выдаёт ошибку и ничего не печатает.
-второй код печатает листы если их скрыть, но в нём нужно перечислять название листов.
Моя задача-записать код который будет печатать листы в которых ячейка  A1 не пуста и будет их печатать даже если эти листы скрыты.
Сижу верчу, кручу эти два кода но ничего так и не вышло.
Буду несказанно благодарен за любую помощь.
Ниже два моих макроса(без Sub и End Sub)


Dim sh As Worksheet
For Each sh In ThisWorkbook.Worksheets
If Not sh.[A1].Value = 0 Then sh.PrintOut Copies:=1
Next sh



Application.ScreenUpdating = False
For Each ws In Sheets(Array("Лист1", "Лист2", "Лист3"))
   With ws
       .Visible = -1
       .PrintOut
       .Visible = 0
   End With
Next
 
 
 
#2
13.05.2013 20:17:18
Попробуйте так:
Код
Sub Test()
  Dim sh As Worksheet, i As Long
  Application.ScreenUpdating = False
  For Each sh In ThisWorkbook.Worksheets
    If Not sh.[A1].Value = 0 Then
      i = sh.Visible
      If i <> xlSheetVisible Then sh.Visible = xlSheetVisible
      sh.PrintOut Copies:=1
      If i <> xlSheetVisible Then sh.Visible = i
    End If
  Next
  Application.ScreenUpdating = True
End Sub
Изменено: ZVI - 13.05.2013 20:18:25
 
 
 
#3
13.05.2013 20:49:22
Ничего себе....Cам вряд ли смог бы написать из двух ЭТОТ код...
Огромное спасибо, всё идеально работает, как и хотелось)
 
 
 
#4
13.05.2013 21:12:49
ZVI не подскажите куда в это код вставить, диалоговое окошко подтверждения перед печатью?

lReply = MsgBox("Уверены? "), vbYesNo + vbQuestion)
If lReply = vbYes Then
 
 
 
#5
13.05.2013 21:15:46
Хотя, наверное это уже наглость...
Буду искать сам.
Спасибо.
 
 
 
#6
13.05.2013 23:21:44
Перед For Each
Код
lReply = MsgBox("Уверены? "), vbYesNo + vbQuestion)
If lReply = vbNo Then Exit Sub'ничего не печатаем

или запрос перед каждым листом:
Код
Sub Test()
  Dim sh As Worksheet, i As Long
  Application.ScreenUpdating = False
  For Each sh In ThisWorkbook.Worksheets
    If Not sh.[A1].Value = 0 Then
      i = sh.Visible
      lReply = MsgBox("Уверены? "), vbYesNo + vbQuestion)
      If lReply = vbYes Then
          If i <> xlSheetVisible Then sh.Visible = xlSheetVisible
          sh.PrintOut Copies:=1
          If i <> xlSheetVisible Then sh.Visible = i
      End If
    End If
  Next
  Application.ScreenUpdating = True
End Sub
Даже самый простой вопрос можно превратить в огромную проблему. Достаточно не уметь формулировать вопросы...
 
 
 
#7
13.05.2013 23:40:50
спасибо, уже нашёл и записал так:, после Application.ScreenUpdating = False

If MsgBox("уверены?", vbExclamation + vbYesNo) <> vbYes Then Exit Sub
 
 
 
#8
15.05.2013 13:19:11
Цитата
oOps: после Application.ScreenUpdating = False
Лучше перед Application.ScreenUpdating = False, т.к. не во всех версиях Excel автоматически восстанавливается обновление экрана
 
 
 
Страницы: 1
Наверх