Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1 2 След.
RSS
Результат вычисления не меньше определенного значения, Требуется, чтобы результат вычисления был не меньше определенного значения
 
#1
21.01.2014 14:11:33
Здравствуйте! Прошу помощи в следующем вопросе. Имеется ячейка I3 (файл с примером прилагается), которая считает общее кол-во отработанного времени и прибавляет один доп. час. Необходимо, чтобы результат в этой ячейке выводился НЕ МЕНЕЕ определенного количества часов. Критерий для этого минимума находится в ячейке E3. Например, если в этой ячейке (E3) записано "1,5", то этот минимум должен быть 6 часов; если "3", то - 7 часов, и т.д. (всего шесть таких вариантов). Подскажите, можно ли все эти условия записать в одной формуле, чтобы минимальный результат выводился на основе вышеозначенных критериев?
 
 
 
#2
21.01.2014 14:15:12
Цитата
чтобы результат в этой ячейке выводился НЕ МЕНЕЕ определенного количества часов
Это как, поясните?
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
#3
21.01.2014 14:20:23
Если больше то выводить что есть, а если меньше то минимум?
 
 
 
#4
21.01.2014 14:21:30
Может так?
 
 
 
#5
21.01.2014 14:35:26
В ячейке I3 есть простенькая формула =(H3*24)-(G3*24)+1, которая считает общее кол-во часов работы.  Допустим H3=12ч., G3=9ч., получаем 12-9+1=4ч. Требуется: если результат меньше 6 часов, то формула автоматически подставляет 6; если больше 6 - считает как обычно. В свою очередь этот минимум (в данном случае 6 часов) также зависит от записи в другой ячейке (в файле с примером это ячейка Е3). То есть, если в E3 записано "1,5", то этот минимум будет 6 часов, если "3", то 8 часов (всего таких различных критериев 6). Таким образом ячейка с формулой (I3) должна должна "понимать" на основе ячейки "Е3" какой минимум ей выставить. Если результат превышает минимум, то считать как обычно.
 
 
 
#6
21.01.2014 14:39:53
Ответ там не подошел?
http://www.excelworld.ru/forum/2-8500-1
 
 
 
#7
21.01.2014 14:39:57
ts-79 точно!
 
 
 
#8
21.01.2014 14:41:08
=ОКРВВЕРХ((H3*24)-(G3*24)+1;ВЫБОР(E3/1,5;6;7;8;9;10;11))
может так?
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
#9
21.01.2014 14:44:20
Ivan.kh то что нужно! Только нельзя ли те данные, которые Вы так сказать "вынесли", содержало само тело формулы?
 
 
 
#10
21.01.2014 14:48:09
Nic70y я бы хотел, чтобы формула =(H3*24)-(G3*24)+1 "понимала" минимальное количество часов на основе определенного критерия
 
 
 
#11
21.01.2014 14:51:10
Можно, только в след. рас предупреждайте о кроссе
Код
 =МАКС((H3*24)-(G3*24)+1;ПРОСМОТР(E3;{1,5;3;4,5;6;7,5;9};{6;7;8;9;10;11}))
З.Ы. Воспользуйтесь формулой, которую предложил Владимир, она тоже работает, но лаконичней
Изменено: Ivan.kh - 21.01.2014 14:53:53
 
 
 
#12
21.01.2014 14:53:30
=МАКС(E3/1,5+5;(H3*24)-(G3*24)+1)
Ну так в чем проблема?
 
 
 
#13
21.01.2014 14:55:24
Nic70y, Вы наиболее талантливы (если следовать принципу краткости)  :D
 
 
 
#14
21.01.2014 15:02:04
off:
Ivan.kh, служу Планете Excel!
Это мне vikktur не разрешает длинные (массивные формулы) писать, только ему не говорите
 
 
 
#15
21.01.2014 15:17:26
Владимир у меня не очень получается с Вашим вариантом. Вот мои точные критерии минимума: если Е3=1, то мин=5, далее по аналогии 1,5=6, 3=7, 5=8, 10=8, 20=8
 
 
 
#16
21.01.2014 15:21:00
Цитата
далее по аналогии
это вся аналогия? так воспользуйтесь вариантом Ivan.kh , только подставьте свои значения или выкладывайте всю правду  :)
Изменено: Nic70y - 21.01.2014 15:21:30
 
 
 
#17
21.01.2014 15:21:04
Nic70y аналогично с Владимиром
 
 
 
#18
21.01.2014 15:30:56
Код
=ЕСЛИ((H3*24)-(G3*24)+1<$E3/1,5+5;$E3/1,5+5;(H3*24)-(G3*24)+1)

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#19
21.01.2014 15:36:00
Nic70y Ivan.kh Да. Это вся аналогия. Воспользовался тем самым вариантом Ivan.kh. То что нужно! Спасибо! Но... Есть один неприемлемый побочный эффект: если ячейка Е3 пуста, то результатом вычисления является #Н/Д, что в свою очередь отражается на итогах всей таблицы. Данные в таблицу вносятся постепенно, а формулы должны быть протянуты на весь столбец. Подскажите, можно ли сделать так, чтобы в случае пустой E3, результатом была "1" или что угодно, что не будет влиять на общий итог таблицы (файл приложил)
 
 
 
#20
21.01.2014 15:38:07
В моём варианте при пустой ячейке E3 будет минимум 5.

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#21
21.01.2014 15:39:23
=ЕСЛИ(E3="";1;формула_которая_Вам_нравиться))

зы. #12 и #18 это в принципе одно и тоже
Изменено: Nic70y - 21.01.2014 15:45:20
 
 
 
#22
21.01.2014 15:44:55
JayBhagavan Спасибо. Но при значении 5 получается 8,3, а хотелось бы 8  :)
 
 
 
#23
21.01.2014 15:50:31
Nic70y Дико извиняюсь, но я не понял Вашего последнего варианта. Каюсь, не силен в непосредственной теме разговора. Посему буду очень признателен за готовое решение  :oops:
 
 
 
#24
21.01.2014 16:09:52
Код
=ЕСЛИОШИБКА(ЕСЛИ((H3*24)-(G3*24)+1<ИНДЕКС({5;6;7;8;8;8};ПОИСКПОЗ($E3;{1;1,5;3;5;10;20};0));ИНДЕКС({5;6;7;8;8;8};ПОИСКПОЗ($E3;{1;1,5;3;5;10;20};0));(H3*24)-(G3*24)+1);(H3*24)-(G3*24)+1)
sigma, извините, невнимательно прочёл условия.
Изменено: JayBhagavan - 21.01.2014 16:11:03 (добавление)

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#25
21.01.2014 16:12:24
Ну например так:
Код
=ЕСЛИ(E3="";1;МАКС((H3*24)-(G3*24)+1;ПРОСМОТР(E3;{1;1,5;3;5;10;15;20};{5;6;7;8;8;8;8})))
 
 
 
#26
21.01.2014 16:18:55
Nic70y, Ваш вариант оптимальней, но он не учитывает, если введут значение отличное от перечисленного автором в ячейке E3. Осмелюсь доработать Ваш вариант:

Код
 =МАКС(ЕСЛИОШИБКА(ИНДЕКС({5;6;7;8;8;8};ПОИСКПОЗ($E3;{1;1,5;3;5;10;20};0));0);($H3*24)-($G3*24)+1)

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#27
21.01.2014 16:23:54
JayBhagavan, это не мой вариант, я ее стырил из файла и дописал, а пока мы всей "правды" не знаем, как и версии офис ТС
ЕСЛИОШИБКА в xls не работает :(
 
 
 
#28
21.01.2014 16:31:14
Nic70y, добро, учёл Ваше замечание:
Код
=МАКС(ЕСЛИ(ЕЧИСЛО(ИНДЕКС({5;6;7;8;8;8};ПОИСКПОЗ($E3;{1;1,5;3;5;10;20};0)));ИНДЕКС({5;6;7;8;8;8};ПОИСКПОЗ($E3;{1;1,5;3;5;10;20};0));0);($H3*24)-($G3*24)+1)
:)

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#29
21.01.2014 16:48:17
JayBhagavan Nic70y Дорогие друзья, огромное человеческое Вам спасибо! Каждый из последних 4-х вариантов подходит идеально. На этом мои поиски, кажется, закончены. За сим откланиваюсь с благодарностью за Ваше время и умственные усилия. Немедля побегу на улицу и всем буду рассказывать какие удивительные люди обитают на планете Excel  :D
 
 
 
#30
21.01.2014 19:01:51
Цитата
Это мне vikktur не разрешает длинные (массивные формулы) писать
Я а страже. Все равно длинная!
=МАКС(E3/1,5+5;(H3-G3)*24+1)
Наказан сочинением 3-х дармовых формул   :)  
=МАКС(ЕСЛИ(ЕЧИСЛО(ИНДЕКС({5;6;7;8;8;8};ПОИСКПОЗ...
функцию ИНДЕКС можно исключить.

Вариант:
=ЕСЛИ(ИЛИ($E3={1;1,5;3;5;10;20});ВПР($E3;{1;5:1,5;6:3;7:5;8:10;8:20;8};2;);($H3-$G3)*24+1)
 
 
 
Страницы: 1 2 След.
Наверх