Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Поиск 5-ти наибольших значений по одному условию
 
#1
17.06.2015 16:58:36
Уважаемые знатоки, прошу помощи. Подскажите как найти 5 наибольших значений по одному условию (в данном случае ФИО)
 
 
 
#2
17.06.2015 17:06:53
Можно такой вот формулой массива (вводить Ctrl+Shift+Enter)
Код
=НАИБОЛЬШИЙ((($G$3:$G$69)*--($F$3:$F$69=M3));L3)
Кому решение нужно - тот пример и рисует.
 
 
 
#3
17.06.2015 17:12:11
Двойной минус. Круто. Спасибо :) Сильно выручил
 
 
 
#4
17.06.2015 17:12:29
еще вариант
Код
=НАИБОЛЬШИЙ(ЕСЛИ($F$3:$F$69=M3;$G$3:$G$69;"");L3)
 
 
 
#5
17.06.2015 17:24:36
Простая (немассивная) формула.
Код
=LARGE(INDEX(($B$3:$B$69=I3)*($C$3:$C$69);0);H3)
Изменено: jakim - 17.06.2015 17:27:34
 
 
 
#6
18.06.2015 05:08:21
Цитата
Антон написал: Двойной минус. Круто.
Только зачем оно в данном случае.  ;)
 
 
 
#7
18.06.2015 08:25:16
Цитата
$F$3:$F$69=M3
для ТС -  слово (по данному условию) ИСТИНА или ЛОЖЬ превращает в число 1 или 0
Цитата
Алишер Шакиров написал: Только зачем оно в данном случае.  
для надёжности  :) ... в массивной формуле - необязательно
чтобы не гадать на кофейной гуще, кто вам отвечает и после этого не совершать кучу ошибок - обратитесь к собеседнику на ВЫ - ответ на ваш вопрос получите - а остальное вас не касается (п.п.п. на форумах)
 
 
 
#8
18.06.2015 08:27:43
Цитата
JeyCi написал: в массивной формуле - необязательно
там есть знак * и поэтому -- не нужно
причем здесь массивная? или я что-то не понял
 
 
 
#9
18.06.2015 08:31:03
Цитата
Catboyun написал: или я что-то не понял
в данной массивной формуле, о которой шла речь - из поста2
там кстати можно обойтись и без столбца L, в 1-ю ячейку рядом с первой фамилией в столбце M
Код
=НАИБОЛЬШИЙ((($G$3:$G$69)*($F$3:$F$69=M3));СЧЁТЕСЛИ($M$3:M3;M3))
тоже ввести, как массивную... и растянуть вниз
Изменено: JeyCi - 18.06.2015 09:09:12
чтобы не гадать на кофейной гуще, кто вам отвечает и после этого не совершать кучу ошибок - обратитесь к собеседнику на ВЫ - ответ на ваш вопрос получите - а остальное вас не касается (п.п.п. на форумах)
 
 
 
#10
18.06.2015 10:57:57
Вот странно
=НАИБОЛЬШИЙ((($G$3:$G$69)*--($F$3:$F$69=M3));L3) и
=НАИБОЛЬШИЙ((($G$3:$G$69)*($F$3:$F$69=M3));СЧЁТЕСЛИ($M$3:M3;M3))
работают
а
=НАИМЕНЬШИЙ((($G$3:$G$69)*--($F$3:$F$69=M3));L3) и
=НАИМЕНЬШИЙ((($G$3:$G$69)*($F$3:$F$69=M3));СЧЁТЕСЛИ($M$3:M3;M3))
выдают нули..
Изменено: Alex1001 - 18.06.2015 10:58:13
 
 
 
#11
18.06.2015 11:01:57
Почему "странно"? Посмотрите, какой массив при пошаговом вычислении формулы формируется и посчитайте, сколько там нулей. Задаете в НАИМЕНЬШИЙ выводить 1-й наименьший - он вам и выводит 0. И так будет пока в параметрах формулы не зададите выводить номер наименьшего, который больше 0. :)
Кому решение нужно - тот пример и рисует.
 
 
 
#12
18.06.2015 11:04:02
В том то и прикол, что нулей в массиве нет) Файл тот же самый значения выбраны случайно в диапазоне больше нуля
Изменено: Alex1001 - 18.06.2015 11:05:52
 
 
 
#13
18.06.2015 11:06:59
Я говорил при пошаговом вычислении смотреть. Знаете, где это? Если нет - п.меню Формулы - вычислить формулу.
Кому решение нужно - тот пример и рисует.
 
 
 
#14
18.06.2015 11:09:10
Код
=НАИМЕНЬШИЙ(ЕСЛИ($F$3:$F$69=M3;$G$3:$G$69);L3)
фрилансер Excel, VBA - контакты в профиле
"Совершенствоваться не обязательно. Выживание — дело добровольное." Э.Деминг
 
 
 
#15
18.06.2015 11:16:49
Посмотрел.. в результате вычисления ($G$3:$G$69)*--($F$3:$F$69=M3)) получается почему то массив с толпой нулей, но второе наименьшее все равно 0 (как и 3е и 4ое) хотя ненулевые в нем тоже есть..
 
 
 
#16
18.06.2015 11:25:04
Alex1001,
А формула Икки тоже не работает?
 
 
 
#17
18.06.2015 11:25:31
Ну так правильно - среди этого массива (с толпой нулей и с ненулевыми значениями) вы задаете показывать 3-й наименьший элемент. Он вам честно показывает третий 0. :) И так будет показывать, пока нули не кончатся. :)
Кому решение нужно - тот пример и рисует.
 
 
 
#18
18.06.2015 11:28:56
Чего то я недогоняю.. Я почему то считал что в массиве 1;2;3;4;0;0;0;0 первый наименьший это 0 а второй это 1.. и как тогда выбрать реальные наименьшие по Петрову к примеру?
 
 
 
#19
18.06.2015 11:51:49
В примере, который вы привели, первый наименьший - 0, второй - 0 и только пятый - 1.
Для того, чтобы понять, какой по номеру будет наименьший больше 0 надо в этом массиве вычислить сколько элементов равно 0.
СЧЁТЕСЛИ(Массив;"=0"), прибавить к найденному количеству 1 и передать это, как номер наименьшего, который надо выводить в формулу.
Кому решение нужно - тот пример и рисует.
 
 
 
#20
18.06.2015 12:02:35
Всем спасибо! Особенно ikki! Респектуважухабл! Коротко и по существу, и все работает! И спасибо Пытливому за прояснение сути!
 
 
 
#21
18.06.2015 12:04:27
Типа такого:
Код
=НАИМЕНЬШИЙ((F3:F16=M3)*(G3:G16);СУММ(ЕСЛИ(F3:F16<>M3;1;0))+1)

формула массива (для данных из первоначального файла-примера
Кому решение нужно - тот пример и рисует.
 
 
 
#22
18.06.2015 12:05:37
Спасибо!
 
 
 
#23
18.06.2015 18:34:02
Посмотрите такой вариант.
В столбце "small" необходимо заменить формулу на такую
Код
=LARGE(INDEX(($F$3:$F$69=M3)*($G$3:$G$69);0);COUNTIF($F$3:$F$69;M3)-L3+1)
Изменено: jakim - 18.06.2015 21:28:03 (ошибка)
 
 
 
Страницы: 1
Наверх