Страницы: 1
RSS
Как вычислить повторяющиеся числа в таблице
 
Помогите вычислить повторяющиеся числа в таблице. Имеются числа от 1 до 50. В строки таблицы, в ручную, добавляются по три числа так, чтобы они между собой в таблице не повторялись. Если три числа (независимо от расположения в правой, левой или средней ячейки) повторяются в таблице, то нужно чтобы ячейка I15 сообщила о том, что такие числа уже имеются в таблице. Более подробное условие во вложении. Заранее спасибо!
 
=СУММПРОИЗВ(1/СЧЁТЕСЛИ(C15:E15;C15:E15))
Покажет количество уникальных в строке. Если 1 или 2, то "караул!".
Или так:
=СУММПРОИЗВ(1/СЧЁТЕСЛИ(C15:E15;C15:E15))=3
=И(C15<>D15;C15<>E15;D15<>E15)
Самая быстрая:
=ЕСЛИ(C15<>D15;ЕСЛИ(C15<>E15;ЕСЛИ(D15<>E15;)))
 
У этих формул нет связи с данными из таблицы. Три числа вводятся в ячейку С15:E15, чтобы в ячейке I15 можно было определить повторяются они в таблице или нет. Если не повторяются таблица соответственно увеличивается.
 
Не так понял.
Сравнение по столбцам:
=СЧЁТЕСЛИ(C3:C12;C15)+СЧЁТЕСЛИ(D3:D12;D15)+СЧЁТЕСЛИ(E3:E12;E15)
Если нужно сравнивать со всей таблицей, измените диапазоны,
или формула массива:
=СЧЁТ(1/СЧЁТЕСЛИ(C3:E12;C15:E15))
 
=ПОИСКПОЗ(3;МУМНОЖ(Ч(СЧЁТЕСЛИ(СМЕЩ(C3:E3;СТРОКА(A3:A12)-3;);C15:E15));{1:1:1});)
Изменено: Владимир - 05.10.2014 14:42:24
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
Владимир, то, что нужно! Огромное Вам СПАСИБО!!!
 
Опять я не так понял.
 
Ребята, помогите, пожалуйста, поправить формулу так, чтобы она считала количество повторений вместо повторяющейся строки. Более подробно во вложении.
 
Код
=СУММПРОИЗВ(($C$3:$C$12=$C$15)*($D$3:$D$12=$D$15)*($E$3:$E$12=$E$15))

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
=СУММПРОИЗВ(--(МУМНОЖ(Ч(C3:E12=C15:E15);{1:1:1})=3))
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
Владимир, спасибо за Вашу формулу. Начинаю понемногу понимать смысл формулы МУМНОЖ.

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
Если есть двухмерный массив - =Ч(C3:E12=C15:E15), то МУМНОЖ самое оно.
----------
Да, и не моё это. Это всё наше.   :)    
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
Владимир, спасибо. Просто в Ваших ответах я чаще всего вижу те формулы, которыми зачастую я ни разу не пользовался и с ходу понять их у меня не получается. :)
И ещё, да простят меня уважаемые модераторы, коль я нарушаю правила, пытался сделать формулу гибче, но результат ЗНАЧ, а именно, при замене {1:1:1} на:
ТРАНСП(Ч(ЕЧИСЛО($C$15:$E$15)))
или на:
ТРАНСП($C$15:$E$15^0)
Что странна, если зайти в формулу, то ответ 2, а в ячейку возвращает результат ЗНАЧ и пошаговый расчёт тоже ЗНАЧ выдаёт. В чём моя ошибка?
Спасибо.

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
А это формула массива, создаёт видимость такой ошибки.  Но в неё можно зайти через F9 и увидеть всё-таки правильный массив.
Если написать  так:
...;ТРАНСП({1;1;1}))=3))
...;C3:C5^0)=3))
...;{1:1:1})=3)
т.е. константы или строки не покажут данную ошибку и массивный ввод не потребуется.
А вот для ссылок на столбцы..;ТРАНСП(C3:E3)^0), где выдаётся данная ошибка, уже требуется массивный ввод.
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
Владимир, да, точно. Спасибо.

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
Владимир[SIZE=4]спасибо ваша формула отлично работает. Скажите, а можно формулу поправить так, чтобы она также показывала одинаковые числа в строках еще и в том случае, если они расположены в этих строках в разнобой, т.е. в разных ячейках?
 
Помогите поправить формулу так, чтобы она считала количество повторений в строках еще и в том случае, если цифры расположены в этих строках в разных ячейках. Более подробно во вложении.
 
Формула массива:
=СЧЁТ(1/(ЧАСТОТА(ЕСЛИ((C3:C12=C15:E15)+(D3:D12=C15:E15)+(E3:E12=C15:E15);СТРОКА(C3:C12));СТРОКА(C3:C12))>2))
 
Вставил формулу, в результате в ячейке I15 показывает ноль  :(
 
Вставили как формулу массива, тремя клавишами (поиск по форуму может подсказать)?
Покажите.
 
Показываю, см. вложение.
 
ФМ - вводится одновременным нажатием Ctrl/Shift/Enter, после чего формула будет обрамлена в фигурные скобки {}. Их я у Вас в ячейке не вижу. Если введете как ФМ, то получите ответ 4, а не 3, как предполагаете (про 11 строку забыли).
 
Все понял, большое Вам спасибо!!!
Страницы: 1
Наверх