Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Удаления текста справа после определенного знака
 
#1
11.11.2019 22:07:13
Добрый вечер!
Помогите пожалуйста написать формулу удаление всего после символа / справа
Т.е.
Аксессуары для ванной комнаты/Ершики/Ершики Wess => Аксессуары для ванной комнаты/Ершики
Аксессуары для ванной комнаты/Полотенцедержатели/Полотенцедержатели Fixsen => Аксессуары для ванной комнаты/Полотенцедержатели

Коллеги как сделать что бы поиск был не слева а справа
Код
=ЛЕВСИМВ(A2;ПОИСК("/";A2)-1)
 
 
 
#2
11.11.2019 22:32:32
Код
=ЛЕВСИМВ(A2;ПРОСМОТР(;-1/(ПОИСК("/";ПСТР(A2;СТРОКА($1:$99);99))=1);СТРОКА($1:$99))-1)

Решил вот так, может кому пригодится!
 
 
 
#3
11.11.2019 22:33:56
Видимо:
=ПРАВСИМВ(А2;ПОИСК("/";А2)-1)
 
 
 
#4
11.11.2019 22:38:33
Макросои
Код
Sub Tablica()
Dim i As Long
Dim iLastRow As Long
 iLastRow = Cells(Rows.Count, 1).End(xlUp).Row
  For i = 1 To iLastRow
    Cells(i, 2) = Left(Cells(i, 1), InStrRev(Cells(i, 1), "/") - 1)
  Next
End Sub
 
 
 
#5
11.11.2019 22:44:44
=LEFT(A2;LEN(A2)-LEN(TRIM(RIGHT(SUBSTITUTE(A2;"/";REPT(" ";99));99)))-1)
на всякий случай лучше подстраховаться
=LEFT(TRIM(A1);LEN(TRIM(A1))-LEN(TRIM(RIGHT(SUBSTITUTE(A1;"/";REPT(" ";99));99)))-1)
Ну и
=SUBSTITUTE(A3;"/"&TRIM(RIGHT(SUBSTITUTE(A3;"/";REPT(" ";99));99));)
=LEFT(A4;FIND("@";SUBSTITUTE(A4;"/";"@";LEN(A4)-LEN(SUBSTITUTE(A4;"/";))))-1)
Изменено: БМВ - 11.11.2019 22:44:55
По вопросам из тем форума, личку не читаю.
 
 
 
#6
11.11.2019 23:22:30
И мой пятак в копилку. Массивная формула:
Код
=ЛЕВБ(A1;МАКС(СТРОКА(1:98)*(ПСТР(A1;СТРОКА(2:99);1)="/")))
 
 
 
Страницы: 1
Наверх