Страницы: 1
RSS
Возврат названия заголовка столбца таблицы по значению в ячейке
 
Здравствуйте. Помогите пожалуйста с формулой. Есть две таблицы. №1 с общим списком сотрудников предприятия и №2 Где все они распределены по отделам. Необходимо в первой таблице проставить название отдела на против фамилии сотрудника в нем работающего. Пробовал с формулой ИНДЕКС, не очень удачно.
Версия 2010г. Спасибо!
 
Здравствуйте. А попробуйте так
Код
=ИНДЕКС($A$20:$D$20;СУММПРОИЗВ(($A$21:$D$24=A4)*СТОЛБЕЦ($A$20:$D$20)))
 
=ПОИСКПОЗ(-1;МУМНОЖ({1;1;1;1};-(A4=$A$21:$D$24));0)
 
Спасибо большое. Обе работают. Сейчас разберусь по элементам...
 
Ещё две формулы
Код
=ИНДЕКС(A$20:D$20;АГРЕГАТ(15;6;СТОЛБЕЦ($A:$H)/($A$21:$D$24=A4);1))
Код
=ИНДЕКС(A$20:D$20;МАКС(ИНДЕКС(СТОЛБЕЦ($A:$D)*($A$21:$D$24=A4);0)))
 
Добрый день! А есть возможность в одной ячейке вывести несколько не уникальных значений с заголовками столбов таблицы? Или хотя бы по одному условию, но несколько заголовков.

Бренд 1 -1, Бренд 2 -1, Бренд 3 - 3, Бренд 5 - 5, где Бренд 1 это заголовок, а 1 это значение в ячейке
 
офис 2019 или новее, формула массива:
Код
=ОБЪЕДИНИТЬ(", ";;ЕСЛИ(ЕПУСТО(B30:F30);"";СЦЕПИТЬ($B$29:$F$29;" - ";B30:F30)))
Изменено: Ігор Гончаренко - 16.03.2022 15:37:07
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
Или так
Код
=ОБЪЕДИНИТЬ(", ";1;ЕСЛИ(B30:F30<>"";$B$29:$F$29&"-"&B30:F30;""))
Изменено: Msi2102 - 16.03.2022 15:40:06
 
Цитата
написал:
офис 2019 или новее, формула массива:
спасибо большое
 
Цитата
написал:
Или такКод ? 1=ОБЪЕДИНИТЬ(", ";1;ЕСЛИ(B30:F30<>"";$B$29:$F$29&"-"&B30:F30;""))
Спасибо большое
 
Добрый всем!
Помогите пожалуйста. Требуется сделать мониторинг по успеваемости учащихся. Так при выборе фамилии учащегося нужно чтобы в ячейке D4 (книга МОН_III) выводило название предмета по которому у него отметка 6
 
Цитата
написал:
выводило название предмета по которому у него отметка 6
таких предметов >=1 почти в каждой строке.  
Изменено: Alien Sphinx - 14.02.2023 04:22:30
Пришелец-прораб.
 
Цитата
написал:
Цитата
написал:
выводило название предмета по которому у него отметка 6
таких предметов >=1 почти в каждой строке.  
У данного учащегося (как в таблице) только одна
 
Цитата
написал:
У данного учащегося
Так вы их выбирать хотите или вам надо список составить со всеми ФИО, которые имеют "только одну" отметку?
Пришелец-прораб.
 
выбираем
 
то есть можно выбрать и того, у кого 2 и более 6-к в строке? И что тогда показывать?
Пришелец-прораб.
 
Для отчета выбирается только учащийся у которого одна шестерка, а рядом , относительно выбранной фамилии, должно отображаться по какому предмету эта шестерка
 
MS365
Код
=XLOOKUP(6,FILTER(табель,табель[Ф.И.О.]=$C4),табель[#Headers])
Пришелец-прораб.
 
Спасибо, буду разбираться
Страницы: 1
Наверх