Страницы: 1
RSS
Импорт примечаний и исправлений из Word в Excel
 
Стоит задача вытащить из документа Word все исправления и примечания в таблицу Excel.
Таблица должна содержать Измененный текст, страницу и дату исправления.
Кто то работал над подобной задачей, отзовитесь плиз)
на англоязычном сайте нашел что то подобное, но не совсем то что надо.
 
MEP, вот пример реализации:
Код
Sub extractRevisions()
    Dim revisionObj As Revision, commentObj As Comment, xlApp As Object, xlWs As Object
    ThisDocument.Activate
    ReDim transfArr(0 To ActiveDocument.revisions.Count + ActiveDocument.Comments.Count)
    transfArr(0) = Array("Автор", "Создатель (?)", "Время изменения", "Тип", "Страница", "Текст", "Примечание/Правка")
    For i = 1 To ActiveDocument.revisions.Count
        Set revisionObj = ActiveDocument.revisions.Item(i)
        transfArr(i) = _
            Array( _
                revisionObj.Author, _
                revisionObj.Creator, _
                revisionObj.Date, _
                revisionObj.Type, _
                revisionObj.Range.Information(wdActiveEndPageNumber), _
                revisionObj.Range.Text, _
                "Правка" _
                )
    Next i
    For i = 1 To ActiveDocument.Comments.Count
        Set commentObj = ActiveDocument.Comments.Item(i)
        transfArr(ActiveDocument.revisions.Count + i) = _
            Array( _
                commentObj.Author, _
                commentObj.Creator, _
                commentObj.Date, "", _
                commentObj.Scope.Information(wdActiveEndPageNumber), _
                commentObj.Range.Text, _
                "Примечание" _
                )
    Next i
    
    Set xlApp = CreateObject("Excel.Application")
    xlApp.Visible = True
    Set xlWs = xlApp.Workbooks.Add
    For i = LBound(transfArr, 1) To UBound(transfArr, 1)
        For j = LBound(transfArr(i), 1) To UBound(transfArr(i), 1)
            xlWs.ActiveSheet.Cells(i + 1, j + 1) = transfArr(i)(j)
        Next j
    Next i
End Sub
In GoTo we trust
 
Спасибо, работает на ура :)
 
Добрый день !

Все работает ! У меня появилась по-сложнее задачка: Примечания стоят в таблицах документа Word, нужно выгруженной таблице (как в предыдущем примере) добавить все поля из той строки таблицы, где стоит примечание. В самом документе может быть множество других (не нужных нам) таблиц. Нашел, что-то подобное (https://www.cyberforum.ru/vba/thread2540854.html), но не создается Excel и выгружается только АБЗАЦ, где стоит Примечание.
Изменено: Der_Meister - 02.04.2021 15:37:54
 
Создайте отдельную тему с названием, отражающим задачу, можно сослаться в ней на эту рему
Страницы: 1
Наверх