=ПОДСТАВИТЬ(A2&" "&C2&". Аналог для"&VLOOKUPCOUPLE2col(B:D;3;D2;1;2;" ";", ");B2&" "&C2&",";"";1)

Function VLOOKUPCOUPLE2col(Table As Variant, _
                           SearchColumnNum As Integer, _
                           SearchValue As Variant, _
                           RezultColumnNum1 As Integer, _
                           RezultColumnNum2 As Integer, _
                           ColumnSep As String, _
                           Separator_ As String, _
                           Optional BezPovtorov As Boolean = True)

'Table - таблица, где ищем
'SearchColumnNum - столбец, где ищем
'SearchValue - данные, которые ищем
'RezultColumnNum - столбец, откуда берём результат
'Separator_ - разделитель, желательно вводить с пробелом в конце
'BezPovtorov - если поставить 0, то будут выведены все повторяющиеся совпадения

    Dim i As Long, tmp As String, vlk

    If TypeName(Table) = "Range" Then Table = Intersect(Table.Parent.UsedRange, Table).Value
    If BezPovtorov Then
        With CreateObject("Scripting.Dictionary")
            For i = 1 To UBound(Table)
                If Table(i, SearchColumnNum) = SearchValue Then
                    tmp = Table(i, RezultColumnNum1) & ColumnSep & Table(i, RezultColumnNum2)
                    If Len(tmp) > Len(ColumnSep) Then
                        If Not .Exists(tmp) Then
                            .Add tmp, 0&
                            vlk = vlk & Separator_ & Table(i, RezultColumnNum1) & ColumnSep & Table(i, RezultColumnNum2)
                        End If
                    End If
                End If
            Next i
        End With
    Else
        For i = 1 To UBound(Table)
            If Table(i, SearchColumnNum) = SearchValue Then
                vlk = vlk & Separator_ & Table(i, RezultColumnNum1) & ColumnSep & Table(i, RezultColumnNum2)
            End If
        Next i
    End If
    If vlk > 0 Then vlk = Mid(vlk, Len(Separator_) + 1) Else vlk = ""
    VLOOKUPCOUPLE2col = vlk
End Function