Наша повседневная работа написания кода так или иначе связана с обращением к ячейкам.
Хотелось бы написать про методы обращения к ячейкам. Если что-то пропустил - не ругайте.
Итак, поехали...
Хотелось бы написать про методы обращения к ячейкам. Если что-то пропустил - не ругайте.
Итак, поехали...
| Код |
|---|
Sub CellsSelection()
Dim cell As Range
Dim severalCells As Range
Dim rng As Range
'=======================================
'Выделяем ячейку F6
'=======================================
Set cell = Range("F6")
Set cell = Cells(6, 6)
Set cell = Cells(6, "F")
Set cell = Cells(81926) ' (16384 * 5) + 6
Set cell = Cells.Item(6, 6)
Set cell = Cells.Cells(6, 6)
'=======================================
'1. Выделяем диапазон D4:G10
'=======================================
Set rng = Range("D4:G10")
Set rng = Range(Cells(4, "D"), Cells(10, "G"))
Set rng = Range(Cells(4, 4), Cells(10, 7))
Set rng = Range("D4", Cells(10, 7))
Set rng = Range("D4", "G10")
Set rng = Range(Range("D4"), "G10")
Set rng = Range("D4").Resize(7, 4)
'Обращаемся к диапазону без привязки к объекту Worksheet
Set rng = Range("Лист1!D4:G10")
'Во всех нижеприведённых методах необходимо
'представить диапазон D4:G10 как лист
'с верхней левой ячейкой A1, то есть мысленно
'переносим D4:G10 в A1. :)
'========================================
'2. Выделяем ячейку F6 в диапазоне D4:G10
'========================================
Set cell = rng.Range("C3")
Set cell = rng(3, 3)
Set cell = rng(11)
Set cell = rng.Item(3, 3)
Set cell = rng.Item(11)
Set cell = rng.Cells(11)
Set cell = rng.Cells(3, 3)
'===========================================
'3. Выделяем ячейку E11 ВНЕ диапазона D4:G10
'===========================================
Set cell = rng(30)
Set cell = rng.Item(30)
Set cell = rng.Cells(30)
Set cell = rng.Range("B8")
Set cell = rng.Cells(8, 2)
Set cell = rng(8, 2)
Set cell = rng.Item(8, 2)
Set cell = rng.Cells(8, 2)
'=============================================
'4. Выделяем диапазон E8:F9 в диапазоне D4:G10
'=============================================
Set severalCells = rng.Range("B5:C6")
Set severalCells = rng.Range("B5", "C6")
'В общем, принцип такой же, что и в пункте 2. :)
End Sub
|
There is no knowledge that is not power
