Переношу файл, надстройка уже установлена. Устанавливаю через Сервис - Надстройки

на разных компьютерах разные пользователи, т.е. на одном user1, на другом user2 и т.д.    
Файлы, которые содержат формулы с пользовательскими функциями при переносе на другой компьютер пытаются обновить данные из надстройки, находящейся по адресу C:\Documents and Settings\имя_пользователя\Application Data\Microsoft\AddIns, а на другом компьютере эта надстройка уже находится по адресу C:\Documents and Settings\какое-то_другое_имя_пользователя\Application Data\Microsoft\AddIns

Да везде, но везде ее путь разный в зависимости от имени пользователя. И на другом компьютере при запуске файла с формулами с пользовательскими функциями, содержащимися в надстройке выскакивает сообщение, что "эта книга содержит связи с другими источниками данных", а при нажатии кнопки обновить "эта книга содержит одну или несколько связей, которые не могут быть обновлены"

The_Prist, а можно уточнить по пункту 1.    
Я книгу excel с пользовательскими функциями сохранил как файл с расширением .xla, потом скопировал в папку c:\Documents ... \Addinc, а потом подключил через Сервис - Надстройки. Всё так? Или можеь быть еще что-то надо было сделать?

The_Prist, VovaK, Юрий М и тот_кто_без_имени спасибо за внимание в моей проблеме.    
The_Prist, перепрописал фунцкии, некоторые стали работать нормально, но некотоые сохраняются нормально, но стоит только этот файл открыть на другом компьютере все равно пытаются найти надстройку на старом месте (т.е. где она лежит на исходном компьютере).  
Всё-таки, это наверное, происки врагов :)  
 
Методом проб и ошибок нашел следующее решение:  
Отключил в файлах (их мало) с пользовательским функциями автоматическое обновление и добавил вот такой макрос:  
 
Private Sub Workbook_Open()  
   Dim DiskName As String  
     
   DiskName = Left(ActiveWorkbook.Path, 1)  
     
   If DiskName <> "C" Then  
       On Error Resume Next  
       ChDir "C:\Documents and Settings\" & Application.UserName & "\Application Data\Microsoft\AddIns\моя_надстройка.xla"  
       ActiveWorkbook.ChangeLink Name:=DiskName & ":\AddIns\моя_надстройка.xla", NewName:= _  
           "моя_надстройка.xla", Type:=xlExcelLinks  
   End If  
     
   Calculate  
End Sub  
не совсем понял как он работает, но работает, такой вариант на данном этапе меня устраивает  
Еще раз спасибо всем за внимание

Код модуля ЭтаКнига книги, использующей функции надстройки MyFunc.xla:  
 
Private Sub Workbook_Open()  
 Const MyAddIn = "MyFunc.xla"  ' <-- менять здесь  
 Dim Lnk, Sh  
 On Error GoTo exit_  
 With ThisWorkbook  
   For Each Lnk In .LinkSources(Type:=xlExcelLinks)  
     If UCase(Lnk) Like UCase("*" & MyAddIn) Then  
       If UCase(Lnk) <> UCase(MyAddIn) Then  
         .ChangeLink Name:=Lnk, NewName:=MyAddIn  
         For Each Sh In .Worksheets  
           Sh.Calculate  
         Next  
         Exit For  
       End If  
     End If  
   Next  
 End With  
exit_:  
End Sub

{quote}{login=Ромичь}{date=29.12.2009 09:26}{thema=}{post}Спасибо за код.  
Единственная проблема остается: нужно в 100 файлов прописать этот код :){/post}{/quote}  
Кто ж знал? Впишите в модуль ЭтаКнига надстройки следующий код:  
 
' ZVI:2009-12-29 http://www.planetaexcel.ru/forum.php?thread_id=11245  
' Автоматическое исправление ссылок на надстройку  
' Код в модуле ЭтаКнига надстройки  
Dim WithEvents App As Application  
 
Private Sub Workbook_Open()  
 Set App = Application  
End Sub  
 
Private Sub App_WorkbookOpen(ByVal Wb As Workbook)  
 Dim MyAddIn, Lnk, Sh  
 MyAddIn = UCase(ThisWorkbook.Name)  
 On Error GoTo exit_  
 With Wb  
   For Each Lnk In .LinkSources(Type:=xlExcelLinks)  
     If UCase(Lnk) Like "*" & MyAddIn Then  
       If UCase(Lnk) <> MyAddIn Then  
         .ChangeLink Name:=Lnk, NewName:=MyAddIn  
         For Each Sh In .Worksheets  
           Sh.Calculate  
         Next  
       End If  
       Exit For  
     End If  
   Next  
 End With  
exit_:  
End Sub