Страницы: 1
RSS
суммирование
 
нужно сложить данные в ячейках, значения которых например 10/5, 15/5, 20/10(в сумме 45/20), т.е. суммируются отдельно числа до слэша и отдельно после.
 
Можно через ПСТР, ДЛСТР и ПОИСК...
 
.
 
моно так
 
Вам законом необходимо запретить давать решения :-)  
Чайникам нет возможности учиться :-)))
 
Формула-шутка:  
{=СУММ(ДЕНЬ(A1:A3))&"/"&СУММ(МЕСЯЦ(A1:A3))}
 
Пробовал - получился вариант тухачевского :)  
Ну, почти - меняем ЗНАЧЕН на 1 и вторую СУММ:  
=СУММ((ЛЕВСИМВ(A1:A3;НАЙТИ("/";A1:A3)-1))*1)&"/"&СУММ(1*(ПРАВСИМВ(A1:A3;ДЛСТР(A1:A3)-НАЙТИ("/";A1:A3))))
 
Здравствуйте, хотелось бы продолжить тему, формула работает если в столбце А есть значения, а если нужно задать определенный диапазон в котором сегодня есть данные а на завтра могут быть заполнены не все ячейки диапазона, т.е. в формуле (СУММ(ЗНАЧЕН(ПСТР(A1:A3;НАЙТИ("/";A1:A3)+1;100)))) диапазон выставить например А1:А10, а данные стоят только в первых трех ячейках, в формуле получается #ЗНАЧ!  
Как учитывать и пустые ячейки тоже?
 
народ, подскажите пожалуйста как просуммировать все цифры четырехзначного числа  
например: в ячейке записано 5413, должно выполнить 5+4+1+3 и получиться 13
 
Работает для текста до 99 символов, суммирует только числа, игнорируя тестовые символы.  
 
=СУММ(ЕСЛИ(ЕЧИСЛО(1*ПСТР(A1;СТРОКА($1:$99);1));1*ПСТР(A1;СТРОКА($1:$99);1)))
 
Забыл добавить. Это формула массива, поэтому вводить нужно через <Ctrl+Shift+Enter>
 
Автор - ZORRO2005:  
=СУММ((ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;{1;2;3;4;5;6;7;8;9};"")))*{1;2;3;4;5;6;7;8;9})
 
Хочу присоединиться к вопросу о пустых ячейках, которые если есть в диапазоне, то результат выдается как #ЗНАЧ!  
Очень понравилась решение vikttur, так как не требует создания дополнительных ячеек.  
 
По сути вопроса: как изменить формулу  
=СУММ(ЗНАЧЕН(ЛЕВСИМВ(A1:A3;НАЙТИ("/";A1:A3)-1)))&"/"&СУММ(ЗНАЧЕН(ПСТР(A1:A3;НАЙТИ("/";A1:A3)+1;ДЛСТР(A1:A3)-НАЙТИ("/";A1:A3))))  
чтобы не учитывались(игнорировались) пустые ячейки в диапазоне.  
 
Заранее благодарен!
Если не можешь победить беспорядок, то надо возглавить его.
 
=СУММ(ЕСЛИОШИБКА(ЗНАЧЕН(ЛЕВСИМВ(A1:A5;НАЙТИ("/";A1:A5)-1));0))&"/"&СУММ(ЕСЛИОШИБКА(ЗНАЧЕН(ПСТР(A1:A5;НАЙТИ("/";A1:A5)+1;ДЛСТР(A1:A5)-НАЙТИ("/";A1:A5)));0))  
 
________________________  
khafizovtt@gmail.com
Учимся сами и помогаем другим...
 
Если использовать эту формулу на примере, то выходит результат: #имя?  
 
И еще, формула должна работать если в ячейке 0 или нет никаких значений?!
 
{quote}{login=olelukoje}{date=21.09.2012 10:17}{thema=суммирование}{post}народ, подскажите пожалуйста как просуммировать все цифры четырехзначного числа  
например: в ячейке записано 5413, должно выполнить 5+4+1+3 и получиться 13{/post}{/quote}Конкретно для этой узконаправленной задачи:  
=суммпроизв(пстр(a1;строка(1:4);1)*1)
 
{quote}{login=}{date=24.09.2012 03:21}{thema=}{post}Если использовать эту формулу на примере, то выходит результат: #имя?  
 
И еще, формула должна работать если в ячейке 0 или нет никаких значений?!{/post}{/quote}Для 2003  
=СУММ(ЕСЛИ(ЕОШ(ПОИСК("/";A1:A5));;--ЛЕВСИМВ(A1:A5;ПОИСК("/";A1:A5)-1)))&"/"&СУММ(ЕСЛИ(ЕОШ(ПОИСК("/";A1:A5));;--ПСТР(A1:A5;ПОИСК("/";A1:A5)+1;ДЛСТР(A1:A5))))  
 
будет работать независимо, пустая ячейка или нет. просто не будет ее учитывать.
 
Михаил С. Очень вам благодарен!    
Теперь на годовой отчет (не бухгалтерия) у меня будет уходить гораздо меньше времени. 4 года делал сверку руками, пересчитывая по несколько раз большой объем чисел.
 
Если в столбце могут быть значения типа т/км; руб/км и т.п., то будет ошибка. Необходимы дополнительные проверки. Думайте сразу.
Страницы: 1
Наверх