Страницы: 1
RSS
Какой формулой можно вычислить букву столбца и имя листа?
 
Какую можно использовать формулу в 2007 экселе чтобы найти указанные параметры. У меня есть формула такого формата =ГИПЕРССЫЛКА("#ЛИСТ4!d"&СТРОКА(D170);"▲"), она позволяет перемещаться между ячейками, так вот строку оно находит само с помощью формулы СТРОКА(), при переносе формулы с одного листа на другой приходится переписывать имя листа и имя столбца. Было бы очень интересно узнать может можно вписать формулы для вычисления имени листа и формулу для вычисления имени столбца пример =ГИПЕРССЫЛКА("#формула вычисления листа!формула вычисления столбца"&СТРОКА(D170);"▲").
Изменено: Tosyan12 - 01.09.2018 18:15:06
 
Если правильно понял замысел
Код
=ГИПЕРССЫЛКА("#"&ПСТР(ЯЧЕЙКА("имяфайла";A1);ПОИСК("]";ЯЧЕЙКА("имяфайла";A1))+1;31)&"!"&ЯЧЕЙКА("адрес";C18);"▼")
Согласие есть продукт при полном непротивлении сторон
 
Вот-вот... Надо было замысел описать, а не путь решения.
 
Sanja, какая часть здесь что вычисляет? Эта часть вычисляет лист "#"&ПСТР(ЯЧЕЙКА("имяфайла";A1), эта часть столбец ищет ПОИСК("]";ЯЧЕЙКА("имяфайла";A1))+1;31)&"!"
Формулу поиска использовать не нужно, я ищу не текст а имя столбца это как вычисление строки с помощью формулы СТРОКА(), мне нужно вернуть столбец(a или d или c) и имя листа нужно найти.
Изменено: Tosyan12 - 01.09.2018 19:24:03
 
Вы попробуйте формулу в файле применить и вычислить ее по частям
Имя листа вычисляет эта часть
Код
ПСТР(ЯЧЕЙКА("имяфайла";A1);ПОИСК("]";ЯЧЕЙКА("имяфайла";A1))+1;31)
Согласие есть продукт при полном непротивлении сторон
 
=АДРЕС(18;3)
=СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(АДРЕС(18;3;2);"$";"  ");3))
=ГИПЕРССЫЛКА("#"&АДРЕС(18;3);"▼")
 
Цитата
Sanja написал: ПСТР(ЯЧЕЙКА("имяфайла";A1);ПОИСК("]";ЯЧЕЙКА("имяфайла";A1))+1;31)
Вставлял весь код работает а по частям нет. Я записал так в место листа вставил ваш код =ГИПЕРССЫЛКА("#"&ПСТР(ЯЧЕЙКА("имяфайла";A1);ПОИСК("]";ЯЧЕЙКА("имяфайла";A1))+1;31)&c&СТРОКА(M18);"▼")
выбивает ошибку вставлял в ячейку j4. Для чего +1;31 эта запись?
 
Вы сломали формулу Sanja, даже не разобравшись что к чему.
Возьмите формулу, вставьте ее в какой-нибудь редактор, и экспериментируйте по частям. Подсказка - количество открывающих и закрывающих скобок в каждой функции обязательно должно совпадать, как, например, в этой формуле - функция ПОИСК имеет три открывающие скобки, значит и изучать ее надо до третьей закрывающей (которая между 31 и &) включительно. Еще одна подсказка - 31 это максимальное количество символов, допускаемых в имени листа.
Что касается темы - посмотрите на формулы, предложенные Catboyun, особенно вторую.
 
Писал ответ по другой ветке. Ниже формула для переходов по горизонтали:
Код
=ГИПЕРССЫЛКА("#ЛИСТ1!"&ПОДСТАВИТЬ(АДРЕС(1;СТОЛБЕЦ(I25);4);1;"")&"25";"◄")

Если говорить про перенос с листа на лист то можно просто из формулы убрать лист:
Код
=ГИПЕРССЫЛКА("#"&ПОДСТАВИТЬ(АДРЕС(1;СТОЛБЕЦ(I25);4);1;"")&"25";"◄")
Изменено: mistergam - 12.10.2019 15:14:25
 
Если уже есть адрес в формуле, то зачем все остальное ?
=ГИПЕРССЫЛКА("#"&АДРЕС(25;СТОЛБЕЦ(I25);;"ЛИСТ1");"◄")
=HYPERLINK("#"&ADDRESS(25,COLUMN(I25),,,"ЛИСТ1");"◄")


Собственно #6 про это.
Изменено: БМВ - 12.10.2019 15:31:12
По вопросам из тем форума, личку не читаю.
 
Тогда формула будет такой, чтобы и номер строки и номер столбца были относительными:
Код
=ГИПЕРССЫЛКА("#"&АДРЕС(СТРОКА(I25);СТОЛБЕЦ(I25);;;"ЛИСТ1");"◄")

Без листа:
Код
=ГИПЕРССЫЛКА("#"&АДРЕС(СТРОКА(I25);СТОЛБЕЦ(I25));"◄")
Страницы: 1
Наверх