Sub Main()
    Dim arr As Variant: arr = GetArr()
    Dim arB As Variant: arB = GetArrCol(arr, 2)
    Dim arC As Variant: arC = GetArrCol(arr, 3)
    Dim arD As Variant: arD = GetArrCol(arr, 4)
    
    OutOpis arB, arC, arD
    OutJurn arr
End Sub
'
Sub OutJurn(arr As Variant)
    Dim sh As Worksheet: Set sh = Worksheets("Журнал на сайт")
    With sh.Range("B1").Resize(UBound(arr, 1), UBound(arr, 2))
        .Value = arr
        .Columns("H:H").Clear
    End With
End Sub
'
Sub OutOpis(arB As Variant, arC As Variant, arD As Variant)
    Dim sh As Worksheet: Set sh = Worksheets("Опись")
    With sh
        .Range("B27").Resize(UBound(arB, 1)).Value = arB
        .Range("C27").Resize(UBound(arC, 1)).Value = arC
        .Range("E27").Resize(UBound(arD, 1)).Value = arD
    End With
End Sub
'
Function GetArrCol(arr As Variant, x As Byte) As Variant
    Dim b As Variant
    ReDim b(1 To UBound(arr, 1) - 1, 1 To 1)
    Dim y As Long
    For y = 2 To UBound(arr, 1)
        b(y - 1, 1) = arr(y, x)
    Next
    GetArrCol = b
End Function
'
Function GetArr() As Variant
    Dim sh As Worksheet: Set sh = Worksheets("Лист для выгрузки")
    
    Dim arr As Variant
    With sh
        arr = .Range(.Cells(1, 1), .Cells(.Rows.Count, "H").End(xlUp))
    End With
    SortArr arr
    GetArr = arr
End Function
'
Function SortArr(arr As Variant) As Variant
    Dim sh As Worksheet
    Set sh = Worksheets.Add
    Dim r As Range
    Set r = sh.Cells(1, 1).Resize(UBound(arr, 1), UBound(arr, 2))
    r = arr
     
    With sh.Sort
        .SortFields.Clear
        .SortFields.Add Key:=r.Range("H2").Resize(UBound(arr, 1) - 1), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange r
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    
    Dim y As Long
    y = Application.Min(21, UBound(arr, 1))
    arr = sh.Cells(1, 1).Resize(y, UBound(arr, 2))
    
    Application.DisplayAlerts = False
    sh.Delete
    Application.DisplayAlerts = True
    
    SortArr = arr
End Function