let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Начало", type date}, {"Окончание", type date}, {"По каким дням недели", type text}, {"Номер", type text}}),
    #"Added Custom" = Table.AddColumn(#"Changed Type", "Список дат", each 
        [ListDates = List.Dates( [Начало], Number.From( [Окончание] - [Начало] ) + 1, #duration(1, 0, 0, 0) ),
         ListDays = List.Transform( Text.ToList([По каким дням недели]), Number.From ),
         Out = List.Select( ListDates, (x) => List.Contains( ListDays, Date.DayOfWeek( x ) + 1 ) )][Out]
    )
in
    #"Added Custom"

let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Начало", type date}, {"Окончание", type date}, {"По каким дням недели", type text}, {"Номер", type text}}),

    #"Added Custom" = Table.AddColumn(#"Changed Type", "list", each
        let
            start = [Начало],
            finish = [Окончание],
            startWday = Date.DayOfWeek([Начало], Day.Monday)+1,
            weekDays = List.Transform(Text.ToList([По каким дням недели]), Number.From)
        in
            List.Sort(
                List.Combine(
                    List.Transform(
                        weekDays,
                        (currentWday)=> 
                            let 
                                startShift = currentWday - startWday + (if currentWday > startWday then 0 else 7),
                                first = start + #duration(startShift, 0, 0, 0)

                            in 
                                List.Generate(
                                    ()=>[day=first],
                                    each [day]<=finish,
                                    each [day=[day]+#duration(7,0,0,0)],
                                    each [day]
                                    )
                        )
                )
            )
        )
in
    #"Added Custom"

let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Начало", type date}, {"Окончание", type date}, {"По каким дням недели", type text}, {"Номер", type text}}),
    #"Added Custom1" = Table.AddColumn(#"Changed Type", "Пользовательская", each 
        [ListDays = List.Buffer( List.Transform( Text.ToList([По каким дням недели]), Number.From ) ),
         Start = [Начало],
         Finish = [Окончание],
         StartWeekDay = Date.DayOfWeek( Start, Day.Monday) + 1,
         RealStart = try List.Select( ListDays, each _ >= StartWeekDay ){0} otherwise ListDays{0},
         DaysCount = List.Count( ListDays ),
         Calc = List.Generate(
            () => [id = List.PositionOf( ListDays, RealStart ), runningDate = Start + #duration(7 * Number.From( RealStart < StartWeekDay ) + RealStart - StartWeekDay, 0, 0, 0)],
            each [runningDate] <= Finish,
            each [id = Number.Mod( [id] + 1, DaysCount ), runningDate = [runningDate] + #duration( 7 * Number.From( id <= [id] ) + ListDays{id} - ListDays{[id]}, 0, 0, 0)],
            each [runningDate] )][Calc]    ),
    #"Expanded {0}" = Table.ExpandListColumn(#"Added Custom1", "Пользовательская")
in
    #"Expanded {0}"

let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    typed = Table.TransformColumnTypes(Source, {{"Начало", Date.Type}, {"Окончание", Date.Type}, {"По каким дням недели", Text.Type}, {"Номер", Text.Type}}),
    calc = Table.AddColumn(typed, "temp", (rec) =>
    let
        intDates = List.Transform(Text.ToList(rec[#"По каким дням недели"]), (textNum) =>
        let
            weekNum = Number.From(textNum),
            startWeekNum = Date.DayOfWeek(rec[Начало], Day.Monday) + 1,
            startDate = rec[Начало] + #duration(weekNum - startWeekNum + (if startWeekNum > weekNum then 7 else 0), 0, 0, 0),
            count = Number.IntegerDivide(Duration.TotalDays(rec[Окончание] - startDate), 7) + 1
        in
            List.Dates(startDate, count, #duration(7, 0, 0, 0))
        )
    in
        List.Combine(intDates)
    ),
    #"Expanded {0}" = Table.ExpandListColumn(calc, "temp"),
    #"Changed Type" = Table.TransformColumnTypes(#"Expanded {0}",{{"temp", type date}})
in
    #"Changed Type"