Страницы: 1
RSS
Расчет среднего значения в диапазоне из разных листов (по одной ячейке) файла при условии исключения значение = 0
 
Здравствуйте, уважаемые форумчане. Очень прошу у Вас помощи формулы для расчета среднего значения в диапазоне из разных листов файла при условии исключения значение = 0

Если бы все нужные значения были бы на одном листе - идеально бы подошла формула СРЗНАЧЕСЛИ(D2:G2;">0"), но нужные данные находятся на разных листах
Суть просьбы: В закладке "Отчет" в ячейке I2 прошу поставить формулу для подсчета средних значений из "Файл1С2","Файл2С2","Файл3С2","Файл4С2"
при условии того, если в закладках С2 = 0, данная ячейка не учитывается при расчете среднего значения в "Отчет" в ячейке I2
Я использую формулу =СРЗНАЧЕСЛИ("Файл1!C2;Файл2!C2;Файл3!C2;Файл4!";">0")... не работает
Заранее огромное спасибо.
 
как вариант
Лень двигатель прогресса, доказано!!!
 
Сергей Огромное Вам спасибо и всех благ
 
Уважаемые участники форума. Я очень извиняюсь. Формула Сергея в Ексель работает идеально:
Код
=СУММПРОИЗВ(СУММЕСЛИ(ДВССЫЛ("'"&$G$2:$G$5&"'!"&АДРЕС(СТРОКА(A2);3;));">0";ДВССЫЛ("'"&$G$2:$G$5&"'!"&АДРЕС(СТРОКА(A2);3;)))/СУММПРОИЗВ(СЧЁТЕСЛИ(ДВССЫЛ("'"&$G$2:$G$5&"'!"&АДРЕС(СТРОКА(A2);3;));">0"))) 
   но в google таблице она не работает (((  
Код
=SUMPRODUCT(SUMIF(INDIRECT("'"&$G$2:$G$5&"'!"&ADDRESS(ROW(A2),3,)),">0",INDIRECT("'"&$G$2:$G$5&"'!"&ADDRESS(ROW(A2),3,)))/SUMPRODUCT(COUNTIF(INDIRECT("'"&$G$2:$G$5&"'!"&ADDRESS(ROW(A2),3,)),">0")))
Помогите пожалуйста как то преобразовать формулу так, чтобы она "читалась" в google таблице
Заренее спасибо !
 
Код
=ArrayFormula(СУММПРОИЗВ(СУММЕСЛИ(ДВССЫЛ("'"&$G$2:$G$5&"'!"&АДРЕС(СТРОКА(A2);3;));">0";ДВССЫЛ("'"&$G$2:$G$5&"'!"&АДРЕС(СТРОКА(A2);3;)))/СУММПРОИЗВ(СЧЁТЕСЛИ(ДВССЫЛ("'"&$G$2:$G$5&"'!"&АДРЕС(СТРОКА(A2);3;));">0"))))
Лень двигатель прогресса, доказано!!!
 
Спасибо огромное, Сергей
еперь формула работает в google таблице, но... она осуществляет только поиск данных (вроде ВПР) только с первого листа, игнорируя другие и почему-то не делает
среднего значения. Если можно - помогите пожалуйста.
Код
=ArrayFormula(SUMPRODUCT(SUMIF(INDIRECT("'"&$G$2:$G$5&"'!"&ADDRESS(ROW(A2),3,)),">0",INDIRECT("'"&$G$2:$G$5&"'!"&ADDRESS(ROW(A2),3,)))/SUMPRODUCT(COUNTIF(INDIRECT("'"&$G$2:$G$5&"'!"&ADDRESS(ROW(A2),3,)),">0"))))
 
ardsa, я в гугл таблицах не работаю ArrayFormula() было предположение о придании массивности формуле данную функцию подсмотрел на просторах этого форума, так что особо не помогу
Лень двигатель прогресса, доказано!!!
 
Доброе время суток.
Google spreadsheet не поддерживает, насколько знаю, ссылку в виде диапазона листов, да и INDERECT не поддерживает цикл по строкам - это не Excel. Так что только лобовое указание, судя по всему
Код
=AVERAGEIF({'Файл1'!C2; 'Файл2'!C2; 'Файл3'!C2; 'Файл4'!C2}; ">0")
Изменено: Андрей VG - 12.08.2020 00:59:13
Страницы: 1
Наверх