let
  prizesNumber = [
    src        = Excel.CurrentWorkbook(){[ Name = "Таблица2" ]}[Content], 
    rename     = Table.RenameColumns ( src, { { "Кластер", "Name" }, { "Количество призовых мест", "Value" } } ), 
    nameToText = Table.TransformColumnTypes ( rename, { { "Name", type text } } ), 
    toRec      = Record.FromTable ( nameToText )
  ][toRec], 
  src = Excel.CurrentWorkbook(){[ Name = "Таблица1" ]}[Content], 
  typed = Table.TransformColumnTypes ( src, { { "Магазин", type text }, { "% выполнения ", Percentage.Type }, { "Кластер", Int64.Type } } ), 
  group = Table.Group (
    typed, 
    { "Кластер" }, 
    {
      {
        "Среднее", 
        ( eachCluster ) =>
          List.Average (
            List.FirstN (
              List.Sort ( eachCluster[#"% выполнения "], Order.Descending ), 
              Record.FieldOrDefault ( prizesNumber, Text.From ( eachCluster[Кластер]{0} ), null )
            )
          ), 
        Percentage.Type
      }, 
      {
        "tbl", 
        ( eachCluster ) =>
          Table.AddIndexColumn (
            Table.Sort ( eachCluster[[Магазин], [#"% выполнения "]], { { "% выполнения ", Order.Descending }, { "Магазин", Order.Ascending } } ), 
            "Место", 
            1
          ), 
        type table [ #"% выполнения " = Percentage.Type, Место = Int64.Type ]
      }
    }
  ), 
  expand = Table.ExpandTableColumn ( group, "tbl", { "% выполнения ", "Магазин", "Место" } ), 
  reorder = Table.ReorderColumns ( expand, { "Магазин", "% выполнения ", "Кластер", "Место", "Среднее" } )
in
  reorder