Страницы: 1
RSS
Игнорировать ноль и пустые ячейки в СЧЁТЕСЛИ()
 
Здравствуйте.

Сия тема есть, но она в архиве.
И решение там есть, но ему больше 10 лет.

Много воды утекло, может что полаконичней появилось вместо этого?
=СЧЁТЕСЛИ(A:A;">0")+СЧЁТЕСЛИ(A:A;"<0")
Компьютер никогда не заменит человека (©️ Hannibal Lecter)
 
вот так себе вариант с новыми:
Код
=СЧЁТ(MAP(A:A;LAMBDA(a;ЕСЛИ(И(ЕЧИСЛО(a);a>0);a;""))))
=СЧЁТ(ФИЛЬТР(A:A;(A:A>0)*ЕЧИСЛО(A:A)))
=СЧЁТ(BYROW(A:A;LAMBDA(a;ЕСЛИ(a=0;"";a))))
Изменено: Тимофеев - 17.05.2022 08:45:21
 
формула массива
Код
=СУММ(--(A:A^2>0))
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
=СУММ(--(A1:A8<>"")), так будет игнорить только пустые
Изменено: Msi2102 - 17.05.2022 08:37:15
 
если есть текст в A, то квадрат не поможет вернёт Знач
Изменено: Тимофеев - 17.05.2022 08:40:33
 
Цитата
написал:
Игнорировать ноль и пустые ячейки
=СУММ(--....) игнорирует)
но текст в А:А - не допустим(((
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
Цитата
Тимофеев написал:
если есть текст в A, то квадрат не поможет вернёт Знач

Спасёт ЕСЛИОШИБКА
Код
=СУММ(--(ЕСЛИОШИБКА(A:A^2;0)>0))

Можно ещё так
Код
=СУММ(--(ЕСЛИОШИБКА(ABS(A1:A8);0)>0))

а ещё можно так
Код
=СУММ(ЕСЛИОШИБКА(A1:A8/A1:A8;0))
Изменено: Msi2102 - 17.05.2022 08:51:39
 
Формула массива
Код
=СЧЁТ(1/A1:E5)

Обычная формула
Код
=СЧЁТ(ИНДЕКС(1/A1:E5;))
Скажи мне, кудесник, любимец ба’гов...
 
Круто. Всем спасибо.
Еще лет на 10 точно закрыли вопрос ))
Компьютер никогда не заменит человека (©️ Hannibal Lecter)
 
Массивные аналоги или серьезно грузят при использовании всего столбца, или требуют ограничения.
Собственно также не лешенная некоторых тормозов замена на COUNTIFS чуть поможет
=COUNTIFS(A:A;"<>0";A:A;"<>";A:A;"<>*")
По вопросам из тем форума, личку не читаю.
Страницы: 1
Наверх