Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Вывести отдельный список текстовых значений, исключая те, что попадаются повторно из единой большой таблицы, за определенную дату., Вывести отдельный список текстовых значений, исключая те, что попадаются повторно из единой большой таблицы, за определенную дату.
 
#1
22.05.2022 12:09:05
Добрый день. Подскажите, возможно ли реализовать формулу в файле с привязкой к условию "определенная дата"? Имеются два листа-на первом листе единая таблица, куда вносятся все данные разными людьми. На втором листе хотелось бы вывести сводную за день. На втором листе есть ячейка, в которой стоит дата-при изменении даты данные подтягиваются с первого листа только по ней. Макросы писать не умею( Пытаюсь адаптировать формулу или массив, но не получается. Красным шрифтом в листе "Сводная за 1 день" выделила формулы, куда пытаюсь привязать проверку условия по дате.
Каждый день может и не быть хорошим. Зато что-то хорошее есть в каждом дне..
 
 
 
#2
22.05.2022 13:01:57
Вариант. (Формула массива).
Код
=IFERROR(INDEX('1'!B$2:B$2000;MATCH(0;COUNTIF(D$4:D4;IF(($C$1>='1'!$A$2:$A$2000)*($C$1<='1'!$A$2:$A$2000);'1'!B$2:B$2000;D$4));)); "")

И еще. Немассивный, с игнором пустых ячеек в диапазоне. Производительность не замерял.
Код
=IFERROR(INDEX('1'!B$2:B$2000;MATCH(1;INDEX(($C$1>='1'!$A$2:$A$2000)*($C$1<='1'!$A$2:$A$2000)*(COUNTIF(B$4:B4;'1'!B$2:B$2000)=0)*('1'!B$2:B$2000<>""););));"")
Изменено: memo - 22.05.2022 13:14:44
 
 
 
#3
22.05.2022 13:28:10
Спасибо вам, добрый человек!  
Каждый день может и не быть хорошим. Зато что-то хорошее есть в каждом дне..
 
 
 
#4
29.05.2022 12:20:07
Цитата
написал:
Вариант. (Формула массива).
Код
    [URL=#]?[/URL]       1      =IFERROR(INDEX(  '1'!B$2:B$2000;MATCH(0;COUNTIF(D$4:D4;IF(($C$1>='1'!$A$2:$A$2000)*($C$1<='1'!$A$2:$A$2000);'1'!B$2:B$2000;D$4));)); "")  
 
И еще. Немассивный, с игнором пустых ячеек в диапазоне. Производительность не замерял.
Код
    [URL=#]?[/URL]       1      =IFERROR(INDEX(  '1'!B$2:B$2000;MATCH(1;INDEX(($C$1>='1'!$A$2:$A$2000)*($C$1<='1'!$A$2:$A$2000)*(COUNTIF(B$4:B4;'1'!B$2:B$2000)=0)*('1'!B$2:B$2000<>""););));"")  
 
=ЕСЛИОШИБКА(ИНДЕКС('1'!C$2:C$2000;ПОИСКПОЗ(1;ИНДЕКС(($C$1>='1'!$A$2:$A$2000)*($C$1<='1'!$A$2:$A$2000)*(СЧЁТЕСЛИ(C$4:C4;'1'!C$2:C$2000)=0)*('1'!C$2:C$2000<>""););));"")

Добрый день. Не сочтите за наглость!!! Но как в эту формулу вставить проверку за месяц? Выдернуть те же самые данные, но за определенный месяц((((
Каждый день может и не быть хорошим. Зато что-то хорошее есть в каждом дне..
 
 
 
#5
29.05.2022 16:31:57
А не лучше ли обычную сводную использовать?
Изменено: surkenny - 29.05.2022 16:53:41
 
 
 
#6
29.05.2022 16:57:04
Там десятки пользователей(( Некоторые почтенного возраста. Проще вывести на отдельный лист, чем научить всех(((
Каждый день может и не быть хорошим. Зато что-то хорошее есть в каждом дне..
 
 
 
#7
29.05.2022 19:35:52
Можно так.
Код
=IFERROR(INDEX('1'!B$2:B$2000;MATCH(1;INDEX(('1'!$A$2:$A$2000>=EOMONTH($C$1;-1)+1)*('1'!$A$2:$A$2000<=EOMONTH($C$1;0))*(COUNTIF(B$4:B4;'1'!B$2:B$2000)=0)*('1'!B$2:B$2000<>""););));"")

Считать будет за весь месяц от первого числа до последнего вне зависимости от указанной в условии даты. Если же нужно считать от указанной даты, то замените этот блок
EOMONTH($C$1;-1)+1 на $C$1.
 
 
 
#8
29.05.2022 20:54:15
🙏🙏🙏Спасибо!
Каждый день может и не быть хорошим. Зато что-то хорошее есть в каждом дне..
 
 
 
Страницы: 1
Наверх