Добрый день. Подскажите, пожалуйста, как на диаграмме можно соединить пустые точки линией? Необходимо, чтобы линия строилась по каждому дню, а если значение за тот или иной день пустое, то линия просто соединялась со следующим не пустым? Файл прикладываю + картинку, что хотелось бы получить.
Nella Che, а что должно быть в промежутке? Очень похоже, что у Вас данные нарастающего итога. Тогда в отсутствующих датах должно быть предыдущее значение: 1. Можно просто в PQ заполнить вниз для заполнения пустых значений предыдущими. Данные должны быть отсортированы по дате. 2. Такая мера:
Код
_2022 =
VAR curDate =
MAX ( 'Сроки продаж'[Дата продаж] )
VAR lDate =
CALCULATE (
MAX ( 'Сроки продаж'[Дата продаж] ),
NOT ISBLANK ( 'Сроки продаж'[2022] ),
'Сроки продаж'[Дата продаж] <= curDate
)
VAR result =
CALCULATE ( SUM ( 'Сроки продаж'[2022] ), 'Сроки продаж'[Дата продаж] = lDate )
RETURN
result
surkenny, извините, а вы бы не смогли подсказать еще, пожалуйста, как в мере откинуть все даты, которые идут после сегодняшней, чтобы на графике линия останавливалась исключительно на сегодня (06.10.2022)? Пример на скрине.
Nella Che, иметь в модели данных справочник календарь со всеми нужными измерениями и фильтрами, в том числе и по типу вашего "Закрытый период". Вот можете почитать. В конце есть файл с календарем.
Nella Che, можно так. В случае диаграммы по дням curMinDate = curDate. В общем случае (допустим, будет группировка по месяцам, где логично выводить сумму на конец месяца) именно min и max.
Код
_2022 =
VAR curMinDate =
MIN ( 'Сроки продаж'[Дата продаж] )
VAR todayDate =
TODAY ()
VAR curDate =
MAX ( 'Сроки продаж'[Дата продаж] )
VAR lDate =
CALCULATE (
MAX ( 'Сроки продаж'[Дата продаж] ),
NOT ISBLANK ( 'Сроки продаж'[2022] ),
'Сроки продаж'[Дата продаж] <= curDate
)
VAR resultSum =
CALCULATE ( SUM ( 'Сроки продаж'[2022] ), 'Сроки продаж'[Дата продаж] = lDate )
VAR result =
IF ( curMinDate <= todayDate, resultSum )
RETURN
result