Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
vlookup(впр) по части слова
 
#1
22.08.2014 09:32:39
Добрый день, подскажите, пожалуйста, можно ли как то сделать vlookup по части слова (текст содержится в ячейке, но не полностью соответствует ей)? Задача примерно следующая: есть массив (название банка и ссылка на сайт банка), есть несколько тысяч разных словосочетаний с названиями этих банков (например: сбербанк адрес, альфабанк москва, сбербанк кредит и тд). Нужно как то расставить ссылки на сайт банка для каждой такой фразы из первого массива.

Пример во вложении.  
 
 
 
#2
22.08.2014 09:45:11
Как найти значение как часть массива - понятно, а вот если в значении (которое мы ищем через vlookup) больше слов чем в массиве - непонятно.
 
 
 
#3
22.08.2014 09:57:27
для данного примера можно так
Код
=ВПР(ПСТР(E1;1;ПОИСК(" ";E1)-1)&"*";$A$1:$B$3;2;)
 
 
 
#4
22.08.2014 09:58:15
Формула массива:
Код
=ИНДЕКС($A$1:$A$3;МАКС(СТРОКА($A$1:$A$3)*ЕЧИСЛО(ПОИСК($A$1:$A$3;$E1))))

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#5
22.08.2014 10:00:41
А если excel английский?)
 
 
 
#6
22.08.2014 10:02:09
osbi, есть переводчик формул. Яндекс в помощь.  ;)
ЗЫ Не стоит так коряво цитировать, достаточно было имя указать и вопрос.  :)
Изменено: JayBhagavan - 22.08.2014 10:02:18

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#7
22.08.2014 10:14:07
Цитата
для данного примера можно так
Спасибо, почти работает. Только вот если перед названием банка из А столбца поставить слово - то будет N/A. Можно это как то решить?

Изменено: osbi - 23.08.2014 12:02:46
 
 
 
#8
22.08.2014 10:42:03
проверяйте
Код
=ПРОСМОТР(99;ПОИСК($A$1:$A$3;E1);$B$1:$B$3)
 
 
 
#9
22.08.2014 10:44:18
модифицированная формула от JayBhagavan  из 4-го сообщения:
Код
=ВПР(ИНДЕКС($A$1:$A$3;МАКС(СТРОКА($A$1:$A$3)*ЕЧИСЛО(ПОИСК($A$1:$A$3;$E1))));$A$1:$B$3;2;ЛОЖЬ)
F1 творит чудеса
 
 
 
#10
22.08.2014 10:46:04
osbi,извините, но у ЮникредитБанка сайт http://www.unicreditbank.ru/ по ссылке что у вас в файле сайт с рекламой(
 
 
 
#11
22.08.2014 10:46:10
Что-то я стратил с формулой. Исправленная формула массива:
Код
=ИНДЕКС($B$1:$B$3;МАКС(СТРОКА($A$1:$A$3)*ЕЧИСЛО(ПОИСК($A$1:$A$3;$E1))))

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#12
22.08.2014 10:53:52
Цитата
Finswimmer пишет:
osbi ,извините, но у ЮникредитБанка сайт http://www.unicreditbank.ru/ по ссылке что у вас в файле сайт с рекламой(
Первое, что в голову попало вбил)
 
 
 
#13
22.08.2014 11:26:26
Цитата
V пишет: =ПРОСМОТР(99;ПОИСК($A$1:$A$3;E1);$B$1:$B$3)
Остановился на этом - делает то что нужно мне. Спасибо всем большое за оперативную помощь.
 
 
 
#14
17.01.2020 16:02:48
Подскажите в этой функции "=ПРОСМОТР(99;ПОИСК($A$1:$A$3;E1);$B$1:$B$3)" за что отвечает "99", что обозначает?  
 
 
 
#15
18.01.2020 00:51:05
Это искомое число.
Но если нужно найти последнее значение в диапазоне, искомое указывают больше возможного максимального числа.
 
 
 
#16
02.04.2023 15:39:08
Подскажите, а как можно здесь выполнить поиск по части слова? К примеру если ввести "альф" - то он бы находил httр://alfa-bank.ru.
А если бы мы ввели "банк" и он встречается в нескольких строках, то все эти строки столбиком бы выдавал.
 
 
 
#17
03.04.2023 10:51:35
Бек,  вам следовало  бы новую тему создать - быстрее бы ответили
да и подобное уже было - задачи однотипные

{  =ЕСЛИОШИБКА(ИНДЕКС($E$1:$E$6;НАИМЕНЬШИЙ(ЕСЛИОШИБКА((ПОИСК($D$11;$E$1:$E$6)>0)*(СТРОКА($E$1:$E$6)-СТРОКА($E$1)+1);"");СТРОКА()-СТРОКА($E$11)+1));"")  }
 
 
 
Страницы: 1
Наверх