Выбрать дату в календареВыбрать дату в календаре

Страницы: 1 2 3 4 5 6 7 8 След.
Записать формулу: Е в степени Х минус арккосинус корень из Х
 
Раз такой нев..... умный - сам и объясняй. И вот тут
Цитата
Андрей VG написал:
Ну, так и надо было писать.
запятая лишняя, изучай пунктуацию, д......

Модераторы, прошу удалить мою учётную запись. Из-за таких...
Закрасить ячейку: две заливки при двух условиях
 
Bema, прощу прощения, что влез. Не увидел Вас в списке присутствующих на сайте.
Записать формулу: Е в степени Х минус арккосинус корень из Х
 
Я же не Вам пишу, а Otktanya
Записать формулу: Е в степени Х минус арккосинус корень из Х
 
Otktanya, эта функция существует только при Х=1 из диапазона [1;10]
Записать формулу: Е в степени Х минус арккосинус корень из Х
 
Цитата
Андрей VG написал:
Кто сказал, что комплексные числа не существуют?
Не в этом случае.
Закрасить ячейку: две заливки при двух условиях
 
user221, встаньте на С2 и посмотрите Условное форматирование - > Управление правилами. Всё просто: если F2 или G2 непустые, т. е. <>"", то ячейка С красится красным, второе условие - наличие единицы в ячейке B, тогда ячейка С красится желтым.
Выборка из диапазона при совпадении в другом диапазоне
 
Проверяйте
Записать формулу: Е в степени Х минус арккосинус корень из Х
 
Otktanya, берите Х от 0 до 1 и через 0,1

Так как Х в формуле под корнем, то область определения функции - диапазон [0;1], т.е. включая 0 и 1
В общем, при Х меньше 0 и больше 1 эта функция не существует, вычислить её нельзя. Надеюсь, так понятно?
Изменено: Wanschh - 16.11.2017 20:54:40
Записать формулу: Е в степени Х минус арккосинус корень из Х
 
Код
=EXP(A1)-ACOS(A1^(1/2))

EXP и ACOS - латинскими буквами, значение X находится в ячейке A1
^ - показатель степени (Shift и цифра 6 основной клавиатуры при английской раскладке)
Сгруппировать данные из строк в столбец по определенному значению, Сгруппировать данные из строк в столбец по определенному значению
 
Цитата
Lunazhan написал:
Не знаю, как быть, если количество дебетов и кредитов не совпадает(((.
А мы-то как можем знать? 8-0  
Сгруппировать данные из строк в столбец по определенному значению, Сгруппировать данные из строк в столбец по определенному значению
 
Если разное количество Дебетов и Кредитов, то как быть?
Почему в примере у Транзакции 170001 Дебет 74301010 и Кредит 62501010, такого нет в исходной таблице.
Если из первых столбцов, то просто, в B6:
=ИНДЕКС(Данные!$B:$Q;ПОИСКПОЗ($A6;Данные!$A:$A;0);ПОИСКПОЗ(B$1;Данные!$B$1:$Q$1;0))
и протянуть.
Сгруппировать данные из строк в столбец по определенному значению, Сгруппировать данные из строк в столбец по определенному значению
 
Совсем недавно решали задачу по приведению таблицы в вид, показанный в файле: здесь
Теперь надо вернуть первоначальную таблицу?
Нужен совет - Обучение excel, книги, он-лайн-курсы, личный тренер
 
На этом же сайте:
http://www.planetaexcel.ru/books/gr-book.php
http://www.planetaexcel.ru/books/mf-book.php
Равенство ячеек на разных листах при заполнении одной из них
 
maxrus163, встаёте на ячейку A1, выделяете остальные листы с помощью Shift, Ctrl и левой кнопки мыши (или ПКМ, Выделить все листы). Вводите значение.
Дальше правой кнопкой мыши на ярлыке листа - Разгруппировать листы.
Извлечение значений из исходной таблицы по определенному критерию
 
Как я понял, нужно что-то такое (формула массива):
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$2:$B$13;НАИМЕНЬШИЙ(ЕСЛИ($A$2:$A$13=$E$1;СТРОКА($B$2:$B$13)-1);СТРОКА()-1));"")
Изменено: Wanschh - 16.11.2017 16:26:47
Подтянуть к значению данные из одного листа в другой (разбивка на дни недели)
 
У Вас в столбце G на листе "по ТТ" день недели со скобками, а на листе "маршрут" - без.
Либо уберите скобки с помощью Ctrl+H (Главная -> Заменить), либо в L2 пишите:
=ИНДЕКС(маршрут!$G:$M;ПОИСКПОЗ(C2;маршрут!$C:$C;0);ПОИСКПОЗ(ПОДСТАВИТЬ(ПОДСТАВИТЬ($G2;")";"");"(";"");маршрут!$G$1:$M$1;0))
у Вас к тому же формула уже неправильно написана
либо ИНДЕКС($A:$M   и потом в конце ПОИСКПОЗ($G2;маршрут!$1:$1...
либо ИНДЕКС($G:$M  и потом  в конце ПОИСКПОЗ($G2;маршрут!$G$1:$M$1...

а у Вас ИНДЕКС($C:$M   ПОИСКПОЗ($G2;маршрут!$1:$1...
в результате номер столбца берется не тот, что нужно, начиная с первого (среда - 9-й столбец), а потом ИНДЕКС выбирает девятый столбец из диапазона $C:$M,
а это - пятница
Условное форматирование цветом по дате и значению в поле
 
А как же это?
Цитата
Sandr написал: Если сегодня 16.11.2017, а дата  окончания подачи заявок  17.11.2017 или 21.11.2017, и количество заявок 0, то ячейка окрашивать в красный цвет. Т.е. если за 2 рабочих дня количество заявок 0.
=($C2=0)*(РАБДЕНЬ($B2;-2)<=0) учтет как сегодняшний день, так и день, указанный в столбце B
Ну или: =ЕСЛИ(ТДАТА()-СЕГОДНЯ()<0,75;($C2=0)*(РАБДЕНЬ($B2;-2)-СЕГОДНЯ()<=0);($C2=0)*(РАБДЕНЬ($B2;-2)-СЕГОДНЯ()<=1))
с учетом сегодняшнего дня до 18-ти часов (0,75 от суток): если до 18-ти часов, то считаем сегодня и день, указанный в столбце В,
если нет - только день указанный в столбце В.
Как массово удались начало строки, Необходимо массово удалить начало строки в ячейке на определенного символа в столбце более 2000 строк
 
Лучше приложите файл Excel с первыми 5-10 строками, этого достаточно.
Если у Вас используется стиль ссылок R1C1, судя по скриншоту, то в соседний столбец:
=ПРАВСИМВ(RC[-1];ДЛСТР(RC[-1])-НАЙТИ(", ";RC[-1])) - выдаст текст
=--ПРАВСИМВ(RC[-1];ДЛСТР(RC[-1])-НАЙТИ(", ";RC[-1])) - выдаст число
Или стандартный инструмент: Данные -> Текст по столбцам, разделитель - "Другой"
Условное форматирование цветом по дате и значению в поле
 
Про рабочие дни не увидел.
=($C2=0)*(РАБДЕНЬ($B2;-2)-$E$1<=2)
Можно еще праздники настроить, если нужно:
=($C2=0)*(РАБДЕНЬ($B2;-2;$G$1:$G$100)-$E$1<=2)
где в диапазоне $G$1:$G$100 - даты праздников
Изменено: Wanschh - 16.11.2017 11:49:29
Условное форматирование цветом по дате и значению в поле
 
Чтобы красить только столбец С достаточно поправить поменять "Применяется к" с =$A$2:$C$9 на =$C$2:$C$9
Условное форматирование цветом по дате и значению в поле
 
Здравствуйте! Если сегодня 16.11.2017, а дата 24.11.2017, как в таком случае красить?
Сколько дней до окончания подачи заявки должно быть, чтобы красилось красным?
Исходя из Ваших условий, достаточно покрасить строки с нулем с столбце С.
Если 2 дня и ноль заявок, то 21.11.2017 красить не надо.
Изменено: Wanschh - 16.11.2017 10:54:41
Условное форматирование процентного интервала в текстовом формате
 
Как вариант
=ИЛИ(--ЛЕВСИМВ(C4;НАЙТИ("-";C4)-1)>=70;ПРАВСИМВ(C4;ДЛСТР(C4)-НАЙТИ("-";C4))*100>=70)
Сцепить, объединить, Как усовершенствовать формулу
 
=ТЕКСТ(A1*100;"#")&"-"&ТЕКСТ(B1;"#%") будет лучше, по-моему.
Возврат всех значений по идентификационному коду
 
Вот ссылки на уроки:
http://www.planetaexcel.ru/techniques/25/2728/ (НАИМЕНЬШИЙ/НАИБОЛЬШИЙ)
http://www.planetaexcel.ru/techniques/2/1790/ (ИНДЕКС)
На самом деле формулы простые, только выглядят страшно. Для дебита:
1) Применяя НАИМЕНЬШИЙ, мы указываем кроме диапазона еще и номер, то есть НАИМЕНЬШИЙ(A1:A20;1) - это самое малое число в диапазоне A1:A20,
НАИМЕНЬШИЙ(A1:A20;2) - следующее за ним и т.д. СТОЛБЕЦ - это чтобы при протяжке вправо менялось наше наименьшее значении (1-е, потом 2-е и т.д.), -1 и -15 чтобы впереди стоящие столбцы или строки отсечь.
2) Так как нам надо, чтобы брались данные из столбца КОД, применяется конструкция ЕСЛИ(ДебетКредит!$A$2:$A$321=$A6;
далее ищется строка с таким значением, -1 здесь потому, что в первой строке - заголовок.
3) По номеру строки функция ИНДЕКС ищет в диапазоне ДебетКредит!$B$2:$B$321 значение с номером строки, полученным в п. 2.
4) Если такого номера нет, выдается ошибка, функция ЕСЛИОШИБКА в случае ошибки просто оставляет ячейку пустой , это "".
Запись СТРОКА() или СТОЛБЕЦ() - это номера строки и столбца, которые соответствуют ячейке, в которой стоит такая формула. Вбейте в A1 =СТОЛБЕЦ() или =СТРОКА() - в обоих случая получите 1.
Изменено: Wanschh - 15.11.2017 07:22:36
Возврат всех значений по идентификационному коду
 
Вариант формулами массива (ввод с помощью Ctrl+Shift+Enter):
для дебета
=ЕСЛИОШИБКА(ИНДЕКС(ДебетКредит!$B$2:$B$321;НАИМЕНЬШИЙ(ЕСЛИ(ДебетКредит!$A$2:$A$321=$A6;СТРОКА(ДебетКредит!$A$2:$A$321)-1);СТОЛБЕЦ()-1));"")
для кредита
=ЕСЛИОШИБКА(ИНДЕКС(ДебетКредит!$F$2:$F$321;НАИМЕНЬШИЙ(ЕСЛИ(ДебетКредит!$E$2:$E$321=$A6;СТРОКА(ДебетКредит!$E$2:$E$321)-1);СТОЛБЕЦ()-15));"")
Изменено: Wanschh - 14.11.2017 21:14:25
Поиск значений через объединенные ячейки
 
Здравствуйте! Количество столбцов в неделе может быть разное?
Поиск в двух столбцах и вывод значения из третьего
 
Вопрос 2:
=СЧЁТЕСЛИ($D$2:$D$15;"Зерно")
или вместо "Зерно" адрес ячейки (см. файл)
Вопрос 1 одной формулой массива (ввод с помощью Ctrl+Shift+Enter):
=ИНДЕКС($D$2:$D$15;ПОИСКПОЗ(МАКС(ЕСЛИ($B$2:$B$15=B24;$E$2:$E$15));ЕСЛИ($B$2:$B$15=B24;$E$2:$E$15);0))
в файле показано, как сделать по отдельности, сначала максимум для сельхозкультуры, потом год, соответствующий ему.
В приведенной формуле поиск максимума урожая для сельхозкультуры вставлен в формулу сразу.

Всё уже расписали :(
Изменено: Wanschh - 10.11.2017 10:18:34
Найти номер полиса по 3 условиям, связка "Индекс" + "Поискпоз" работает некорректно без сортировки
 
SergeyRudometov, впишите поиск точного соответствия в формулу:
=ИНДЕКС($B$2:$B$4;ПОИСКПОЗ($B$6&B7&"Канал2";$C$2:$C$4&$D$2:$D$4&$E$2:$E$4;0))
По умолчанию там 1, то есть поиск максимального значения, которое меньше искомого, подходит для списка, отсортированного по возрастанию.
Если список не отсортирован - нужно точное соответствие.
Другой вариант написания: =ИНДЕКС($B$2:$B$4;ПОИСКПОЗ($B$6&B7&"Канал2";$C$2:$C$4&$D$2:$D$4&$E$2:$E$4;)), как в варианте Ігор Гончаренко,

Вы же пишете 0 в ВПР для точного совпадения :)
Изменено: Wanschh - 09.11.2017 18:47:03
Поиск значений из таблицы, которые соответствуют условиям заданным в ячейках
 
Формула массива (Ctrl+Shift+Enter):
=СУММ(ЕСЛИ((Путевки[[Дата]:[Дата]]=$N$4)*(Путевки[[Автомобиль]:[Автомобиль]]=$H9)*(Путевки[[#Заголовки];[О ДО]:[Т П]]=R$5);Путевки[[О ДО]:[Т П]]))
Или просто формула:
=СУММПРОИЗВ((Путевки[[Дата]:[Дата]]=$N$4)*(Путевки[[Автомобиль]:[Автомобиль]]=$H7)*(Путевки[[#Заголовки];[О ДО]:[Т П]]=AN$5)*(Путевки[[О ДО]:[Т П]]))
Такие штуки, как Путевки[[Дата]:[Дата]] - это для того, чтобы при копировании названия столбцов в smart-таблице "Путевки" не менялись.
Только при изменении даты надо менять ссылку с $N$4 на $Y$4 и т.д. Попробую доработать формулу.
Изменено: Wanschh - 09.11.2017 12:42:16
Условное форматирование по двум критериям.
 
Вроде бы достаточно в формуле написать (для диапазона $G$2:$G$289):
=И($B2<>"закрыт";$G2<=$A$1)
Изменено: Wanschh - 08.11.2017 15:28:44
Страницы: 1 2 3 4 5 6 7 8 След.
Наверх